% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            ticlex2.dtr                                              %
% Purpose:         subset of the lexicon used for the POETIC project        %
% Author:          Lynne Cahill, 15 December 1992                           %
% Email:           lynneca@cogs.sussex.ac.uk                                %
% Address:         COGS, Sussex University, Brighton BN1 9QH, UK            %
% Related files:   ticlex1.dtr                                              %
% Version:         4.11                                                     %
%                                                                           %
%      Copyright (c) University of Sussex 1992.  All rights reserved.       %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% This file contains all the non-leaf nodes of the full lexicon used in the
% Sussex POETIC message understanding system, plus all the lexical items
% that begin with the letter "S" that are contained in that lexicon.

#   atom L E E2 E3 Z M R X Y A D V P1 P2 S N O1 O2 { } .

#   vars $dir: n s e w cl acl.

% Abstract DATR nodes for general lexicon:

%-- basic category nodes --------------------------------------------------

CATEGORY:
        <> == false
        <cat> == cat
        <synargs> == { type "<type>" }
        <syntax> == { "<cat>" [ "<synargs>" ] }
        <semantics> == [ L X true ]
        <true_ending> == <end Node1:<init_ending>>
%       <true_ending> == null
        <end null> == "<ending>"
        <end> == Node1:<init_ending>
        <ending> == Node1:<init_ending>
        <subcat> == 0.

ADJECTIVE: 
        <> == CATEGORY
        <cat> == adjective
        <type> == @property
        <subjtype> == @@entity
        <synargs> == { subjtype "<subjtype>" } CATEGORY
        <semantics> == [ L X "<rootsem>" ]
        <rootsem> == true.

NOUN:   
        <> == CATEGORY
        <cat> == n
        <num> == sing
        <num s> == plur
        <synargs> == { num <num "<true_ending>"> } CATEGORY
        <semantics> == [ L X [ "<semfunc>" X ] ].

CONJ:   
        <> == CATEGORY
        <cat> == conj
        <conj> == yes
        <synargs> ==  { npconj "<conj np>" } { vpconj "<conj vp>" }
                      { sconj "<conj s>" } CATEGORY .

NOUN1:  
        <> == NOUN
        <type> == @event
        <objtype> == @@entity
        <synargs> == { objtype "<objtype>" }
                     { objprep "<objprep>" }
                     { subcat "<subcat>" }
                        NOUN
        <subcat> == pp
        <objprep> == of
        <lambdas> == L Y L X
        <semantics> == [ "<lambdas>" "<rootsem>" ].

VERB:   
        <> == CATEGORY
        <cat> == [ v "<subcat>" ]
        <type> == @event
        <subjtype> == @@entity
        <objtype> == @@entity
        <obj2type> == @@entity
        <objprep> == 0
        <obj2prep> == 0
        <subcat> == 0
        <synargs> == { subcat "<subcat>" }
                     { subjtype "<subjtype>" }
                     { objtype "<objtype>" }
                     { obj2type "<obj2type>" }
                     { subjprep "<subjprep>" }
                     { objprep "<objprep>" }
                     { obj2prep "<obj2prep>" }
                     { passive "<passive>" }
                     { ending "<true_ending>" }
                     CATEGORY 
        <semantics> == [ "<lambdas>" [ and [ time E <tense> ]
                                           "<rootsem>" ] ]
        <lambdas> == L O1 L E L S
        <passive> == <pass "<true_ending>">
        <pass> == no
        <pass ed> == poss
        <pass en> == poss
        <pass ing> == poss
        <tense> == <ten "<true_ending>">
        <ten> == pres
        <ten ing> == pres_fut
        <ten ed> == past.

ADVERB: 
        <> == CATEGORY
        <cat> == adverb.

ADVERBNS:
        <> == CATEGORY
        <cat> == adverbns.

AUX_NOTENSE:
        <> == CATEGORY
        <cat> == aux_notense
        <passive> == no
        <synargs> == { passive "<passive>" }.

DET:    
        <> == CATEGORY
        <cat> == det.

NUMBER: 
        <> == CATEGORY
        <cat> == number
        <type> == @number.

PADJ_P: 
        <> == CATEGORY
        <cat> == padj_p
        <type> == @event
        <synargs> == { alone "<alone>" }
                     { npmod "<npmod>" }
                     CATEGORY .

PART:   
        <> == CATEGORY
        <cat> == part
        <synargs> == { proot "<proot>" }.

RELPRON:
        <> == CATEGORY
        <cat> == relpron.

PREP:   
        <> == CATEGORY
        <cat> == prep.

UNIT:   
        <> == CATEGORY
        <cat> == unit
        <semantics> == [ L N [ N "<unit>" ] ].

MISCNOUN:
        <> == CATEGORY
        <cat> == miscnoun.

SCONJ:  
        <> == CONJ
        <conj> == no
        <conj s> == yes.

VPCONJ: 
        <> == CONJ
        <conj> == no
        <conj vp> == yes.

NPCONJ: 
        <> == CONJ
        <conj> == no
        <conj np> == yes.

AUX_PRES:
        <> == AUX_NOTENSE
        <cat> == aux_pres.

AUX_PAST:
        <> == AUX_NOTENSE
        <cat> == aux_past.

AUX_FUT:
        <> == AUX_NOTENSE
        <cat> == aux_fut.

AUX_PASS:
        <> == AUX_NOTENSE
        <cat> == aux_pass
        <passive> == yes.

POLABBR:
        <> == POLICE
        <cat> == polabbr
        <semantics> == [ L X true ].

ROAD_END:
        <> == CATEGORY
        <cat> == road_end.

TITLE:  
        <> == CATEGORY
        <cat> == title
        <type> == @participant.

DEGREE: 
        <> == ADJECTIVE
        <type> == @meta_prop
        <subjtype> == @@event
        <semantics> == [ L E [ degree E "<semfunc>" ] ].

ADJ_P:  
        <> == ADJECTIVE
        <cat> == adj_p
        <alone> == yes
        <direction> == no
        <npmod> == no
        <synargs> ==  { objtype "<objtype>" }
                      { direction "<direction>" }
                      { alone "<alone>" }
                      { npmod  "<npmod>" }
                      ADJECTIVE 
        <semantics> == [ L Y L X L E "<rootsem>" ].

DIR_ADJP:
        <> == ADJ_P
        <type> == @location
        <subjtype> == @@event
        <objtype> == @@location
        <objprep> == of
        <direction> == yes
        <npmod> == yes
        <semantics> == [ L X L Y L D L V [ and [ from X Y V ]
                                               [ and [ direction V "<dir>" ]
                                                     [ magnitude V D ] ] ] ].

DIR_CORE: 
        <> == ADJECTIVE
        <type> == @location
        <$dir> == $dir.

DIRA:   
        <> == DIR_CORE
        <subjtype> == @@road_part
        <rootsem> == [ and [ carriageway X ]
                           [ direction X <> ] ].

DIRB:   
        <> == DIR_CORE
        <subjtype> == @@traffic
        <semantics> == [ L X L R [ and [ at X R ]
                                       [ and [ carriageway R ]
                                             [ direction R <> ] ] ] ].

DIRC:   
        <> == DIR_CORE
        <cat> == adjpp
        <subjtype> == @@event
        <npmod> == yes
        <alone> == yes
         <synargs> == ADJ_P
        <semantics> == [ L X L E L R [ and [ at X R ]
                                           [ and [ carriageway R ]
                                                 [ direction R <> ] ] ] ].


DIRECTION:
        <> == [ poly "DIRA" "DIRB" "DIRC"]
        <semantics> == [ poly "DIRA:<semantics "<dir>">"
                              "DIRB:<semantics "<dir>">"
                              "DIRC:<semantics "<dir>">" ].

VEH_ADJ:
        <> == ADJECTIVE
        <subjtype> == @@vehicle.

PART_ADJ:
        <> == ADJECTIVE
        <subjtype> == @@participant
        <rootsem> == [ participant X ].

INC_LOC:
        <> == LOCATION
        <type> == @incident_location
        <semantics> == [ L X L Y [ and [ incident Y ] [ at Y X ] ] ].

OTHER_LOC:
        <> == LOCATION
        <type> == @other_loc
        <semantics> == [ L X true ].

PUB_TYPE:
        <> == LOCATION
        <cat> == pub_type.

STREET_TYPE:
        <> == LOCATION
        <cat> == street_type
        <type> == @road.

AGENT:  
        <> == NOUN
        <type> == @agent
        <semfunc> == agent.

POLICE: 
        <> == AGENT
        <type> == @police
        <semfunc> == police.

NONPOLICE:
        <> == AGENT
        <type> == @nonpolice
        <semfunc> == nonpolice.

SERVICE: 
        <> == NONPOLICE
        <type> == @service
        <semfunc> == service.

NONSERVICE: 
        <> == NONPOLICE
        <type> == @nonservice
        <semfunc> == nonservice.

PARTICIPANT:
        <> == NONSERVICE
        <type> == @participant
        <semfunc> == participant.

MEDIA:  
        <> == NONSERVICE
        <type> == @media
        <semfunc> == media.

PRONOUN:
        <> == <"<person>">
        <person> == +3rd
        <cat> == pron
        <-3rd> == POLICE:<>
        <+3rd> == NONPOLICE:<>.

POLTITLE: 
        <> == POLICE
        <cat> == poltitle.

POLICENUM:
        <> == POLICE
        <cat> == policenum
        <semantics> == [ L X true ].

PHYSOBJ:
        <> == NOUN
        <type> == @physobj
        <semfunc> == physobj.

VEHICLE:
        <> == PHYSOBJ
        <type> == @vehicle
        <semfunc> == vehicle.

HGV:    
        <> == VEHICLE
        <type> == @hgv
        <semfunc> == hgv.

PSV:    
        <> == VEHICLE
        <type> == @psv
        <semfunc> == psv.

PMV:    
        <> == VEHICLE
        <type> == @pmv
        <semfunc> == pmv.

TWV:    
        <> == VEHICLE
        <type> == @twv
        <semfunc> == twv.

ROAD_EQUIP:
        <> == PHYSOBJ
        <type> == @road_equipment
        <semfunc> == road_equipment.

HOSP:   
        <> == OTHER_LOC
        <type> == @hosp
        <semfunc> == hosp.

FB:     
        <> == SERVICE
        <type> == @fb
        <semfunc> == fb.

LA:     
        <> == SERVICE
        <type> == @local_authority
        <semfunc> == local_authority.

RECOV:  
        <> == SERVICE
        <type> == @recov
        <semfunc> == recov.

UTILITY:
        <> == SERVICE
        <type> == @utility
        <semfunc> == utility.

FLUID:  
        <> == PHYSOBJ
        <type> == @fluid
        <semfunc> == fluid.

FUEL:   
        <> == FLUID
        <type> == @fuel
        <semfunc> == fuel.

MEDIA:  
        <> == NONSERVICE
        <type> == @media
        <semfunc> == media.

ROAD_PART:
        <> == NOUN
        <type> == @road_part
        <semfunc> == road_part.

ROAD:   
        <> == ROAD_PART
        <type> == @road
        <semfunc> == road.

VEH_PART:
        <> == NOUN1
        <type> == @veh_part
        <objtype> == @@vehicle
        <rootsem> == true.

SOLID:
        <> == PHYSOBJ
        <type> == @solid
        <semfunc> == solid.

% geographical abstract nodes

DB_TOWN:
        <> == LOCATION
        <cat> == db_town
        <semantics> == [ L X [ and [ town X ]
                                   [ and [ called X "<name>" ]
                                         [ grid_ref X [ "<grid_ref>" ] ] ] ] ].

DB_ROAD:
        <> == LOCATION
        <cat> == db_road
        <type> == @road
        <semantics> == [ L X [ and [ road X ]
                                   [ called X "<name>" ] ] ].

DB_ROADPLACE:
        <> == DB_ROAD
        <semantics> == [ L X [ and [ landmark X ]
                                   [ and [ called X "<name>" ]
                                         [ grid_ref X [ "<grid_ref>" ] ] ] ] ].

JUNCNUM:
        <> == LOCATION
        <type> == @junc
        <semantics> == [ L X [ and [ junc X ]
                                   [ and [ called X "<name>" ] ] ] ].

V_PP:   
        <> == VERB
        <subcat> == pp.

V_NP_PP:
        <> == VERB
        <subcat> == np_pp.

V_NP:   
        <> == VERB
        <subcat> == np.

V_NP_S: 
        <> == VERB
        <subcat> == np_s.

V_S:    
        <> == VERB
        <subcat> == s.

V_PNP_PP:
        <> == VERB
        <subcat> == pnp_pp.

V_VP:   
        <> == VERB
        <subcat> == vp.

V_PP:   
        <> == VERB
        <subcat> == pp.

V_AP:   
        <> == VERB
        <subcat> == ap.

V_PART: 
        <> == VERB
        <subcat> == part.

V_PNP:  
        <> == VERB
        <subcat> == pnp.

V_NP_AP:
        <> == VERB
        <subcat> == np_ap.

V_NP_PART:
        <> == VERB
        <subcat> == np_part.

WEATHER:
        <> == NOUN
        <type> == @traffic_prob_cause
        <semantics> == [ L E [ "<weather>" E ] ].

OBSTRUCTION:
        <> == NOUN
        <type> == @obstruction
        <semantics> == [ L X [ obstruction X [ L X true ] [ L X true ] ] ].

HAZARD: 
        <> == NOUN
        <type> == @hazard
        <semfunc> == hazard.

LOCATION:
        <> == NOUN
        <type> == @location
        <semfunc> == location.

COP:    
        <> == VERB
        <cat> == cop.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% The lexical entries that begin with the letter "S":

Same1:  
        <> == ADJECTIVE.

Seem1:  
        <> == V_VP
        <semantics> == [ L O1 L E L S [ modality E possible ] ].

Several1:
        <> == NUMBER
        <semantics> == 3.

She1:   
        <> == PRONOUN.

Since1: 
        <> == AtB
        <alone> == no.

Single_lane1:
        <> == NOUN1
        <type> == @salt
        <objtype> == @@road_part
        <semantics> == [ L O1 L E L S [ salt E O1 ] ].

Slash1: 
        <> == Junction1.

So1:    
        <> == SCONJ.

So2:    
        <> == Very1.

Some1:   
        <> == DET.

Sometime1:
        <> == NOUN
        <type> == @duration
        <semantics> == [ L X [ magnitude X big ] ].

Soon1:  
        <> == ADVERB
        <semantics> == [ L X [ time X fut ] ].

Still1: 
        <> == ADVERB
        <semantics> == [ L E true ].

Sure1:  
        <> == ADJECTIVE.

Saint1: 
        <> == NOUN
        <type> == saint
        <semantics> == [ L X true ].

Saloon1:
        <> == [ poly "PMV" "VEH_ADJ" ].

Scene1: 
        <> == INC_LOC.

School1:
        <> == LOCATION.

Section1:
        <> == MISCNOUN. % don't know what this is supposed to mean
                        % so deleted semantics!

SendA:  
        <> == AdviseC
        <objtype> == @@service
        <rootsem> == [ L X L Y [ enroute E O1 X Y ] ].

SendB:  
        <> == Pass1.

Sergeant1:
        <> == POLTITLE.

Serious1:
        <> == Bad1.

Services1:
        <> == SERVICE
        <semfunc> == service.

SetA:   
        <> == ResetA.

SetB:   
        <> == ResetB.

SetC:   
        <> == ResetC.

SetD:   
        <> == ResetD.

Severe1:
        <> == Bad1.

ShedA:  
        <> == LeakA
        <objtype> == @@solid
        <rootsem> == [ shed_load E O1 [ L X true ] S ].

ShedB:  
        <> == ShedA
        <ending> == ed.

Sheep1: 
        <> == SOLID.

Should1:
        <> == Must1.

Show1:  
        <> == V_NP
        <type> == @non_traffic_prob
        <subjtype> == @@road_equipment
        <objtype> == @@colour
        <rootsem> == true.

Side1:  
        <> == [ poly "VEH_PART" "ROAD_PART" ].

SignA:  
        <> == ROAD_EQUIP
        <semfunc> == sign.

SignB:  
        <> == VERB
        <type> == @non_traffic_prob
        <subjtype> == @@service
        <rootsem> == true.

Sleet1: 
        <> == WEATHER
        <semantics> == [ L E [ and [ snow E ]
                                   [ degree E partial ] ] ].

Slight1:
        <> == Partial1.

Slightly1:
        <> == Partially1.

Slow1:  
        <> == ADJECTIVE
        <semantics> == [ L X true ].

Small1: 
        <> == Partial1.

Snow1:  
        <> == WEATHER
        <weather> == snow.

Someone1:
        <> == PARTICIPANT.

South1: 
        <> == DIR_ADJP
        <dir> == s.

Southbound1:
        <> == DIRECTION
        <dir> == South1.

Spill1: 
        <> == LeakA.

Spillage1:
        <> == LeakC.

Square1:
        <> == STREET_TYPE.

Stadium1:
        <> == LOCATION.

Stand1: 
        <> == V_NP_PART
        <type> == @non_traffic_prob
        <subjtype> == @@service
        <objtype> == <subjtype>
        <obj2type> == down
        <rootsem> == [ L E2 L X L Y [ and [ ending E O1 E2 ]
                                          [ attend O1 X Y ] ] ]
        <lambdas> == L O1 L O2 L E L S.

Start1: 
        <> == ROAD_END.

Steps1: 
        <> == STREET_TYPE.

StickA: 
        <> == Fail1
        <subcat> == pp
        <objtype> == @@colour
        <objprep> == on
        <rootsem> == [ and [ functioning E S ]
                           [ degree E 0 ] ].

StickB: 
        <> == VERB
        <type> == @obstruction
        <subjtype> == @@vehicle
        <lambdas> == L E L S
        <rootsem> == [ obstruction E S [ L X true ] ].

StickC: 
        <> == Fail1.

Street1:
        <> == STREET_TYPE.

Strike1:
        <> == Hit1.

SuggestA:
        <> == RequestA.

SuggestB:
        <> == RequestB.

SuggestC:
        <> == RequestC.

SuggestD:
        <> == RequestD.

SuggestE:
        <> == RequestE.

Sup1:   
        <> == POLICENUM.

Surface1:
        <> == ROAD_PART. % ???

Swt1:   
        <> == Congestion1
        <semantics> == [ L X [ swt X ] ].

Solid1: 
        <> == Heavy2.

Subsidence1:
        <> == NOUN
        <type> == @subsidence
        <semantics> == [ L X [ subsidence X [ L X true ] ].

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

#  show <syntax> <semantics>.

#  hide CATEGORY ADJECTIVE NOUN CONJ NOUN1 VERB ADVERB AUX_NOTENSE DET NUMBER
        PADJ_P PART RELPRON PREP UNIT MISCNOUN SCONJ VPCONJ NPCONJ AUX_PRES
        AUX_PAST AUX_FUT AUX_PASS POLABBR ROAD_END TITLE DEGREE ADJ_P
        DIR_ADJP DIR_CORE DIRA DIRB DIRC DIRECTION VEH_ADJ PART_ADJ INC_LOC
        OTHER_LOC PUB_TYPE STREET_TYPE AGENT POLICE NONPOLICE SERVICE
        NONSERVICE PARTICIPANT MEDIA PRONOUN POLTITLE POLICENUM PHYSOBJ
        VEHICLE HGV PSV PMV TWV ROAD_EQUIP HOSP FB LA RECOV UTILITY FLUID
        FUEL MEDIA ROAD_PART ROAD VEH_PART SOLID DB_TOWN DB_ROAD
        DB_ROADPLACE JUNCNUM V_PP V_NP_PP V_NP V_NP_S V_S V_PNP_PP V_VP V_PP
        V_AP V_PART V_PNP V_NP_AP V_NP_PART WEATHER OBSTRUCTION HAZARD
        LOCATION.

% The next line is the Revision Control System Id: do not delete it.
% $Id: archive.dtr,v 1.1 1997/04/09 20:40:33 root Exp $