% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            rusverbs.dtr                                             %
% Purpose:         a fragment of the verbal system of Russian               %
% Author:          Dunstan Brown, December, 1995                            %
% Email:           lis1db@surrey.ac.uk                                      %
% Address:         LIS, University of Surrey, Guildford GU2 5XH             %
% Documentation:   russian.doc                                              %
% Related files:   rusvlex.dtr, rusvdec.dtr, rusnoms.dtr                    %
% Version:         2.08                                                     %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# load 'rusvlex.dtr'.
# load 'rusvdec.dtr'.

% This file is a theoretical fragment of Russian which has been developed
% to account for the first 700 verbs from Zasorina's (1977) frequency
% dictionary.  It should be used with the lexicon rusvlex.dtr and the
% file rusvdec.dtr.
%
% The order of items in the file is as follows.
%
% 1) The load declarations for for rusvlex.dtr and rusvdec.dtr.
%
% 2) The part of the Word Class Hierarchy which deals with the
%    the verbal system.  It contains the node WORD VERB and
%    REFL_VERB (reflexive verb).
%
% 3) A switch section which is involved in:
%      determination of conjugation (the node CONJ)
%      determination of the form of the future based on aspect
%      determination of the form of the present based on aspect
%      determination of the form of the masculine singular past
%      determination of the form of the infinitive
%      provision of a _j between two vowels (the node JOT)
%      determination of the form of the reflexive suffix
%      (the nodes REFLEXIVE_SUFFIX, WHICH_SUFFIX SUFFIX_S'A
%      and SUFFIX_S')
%
% 4) The verbal inflection hierarchy.
%
% 5) A hierarchy of stems (where a stem is a prefix, possibly null,
%    plus a base).
%
% 6) A hierarchy of bases.  The path <base 1> gives the form of 
%    the base (and  stem) used in the infinitive and past.  The 
%    path <base 2> gives the form of the base (and stem) used in
%    the present.  The path extensions <base 1 b> and <base 2 a>
%    give the form of the base (and stem) used in the past and the
%    first person present/future, when these differ from the infinitive
%    and other forms of the present/future.
%    The path <base vocal> gives the vowel which occurs in the 
%    base/stem in the infinitive and the past, and by default the present.
%    Consonantal bases/stems do not have a <base vocal> in <base 2> and
%    its extensions <base 2 a>, as here a consonant occurs directly
%    before the theme vowel (<mor vowel>) of inflection.
%    The path <base habitual>, and its extensions, define information
%    about secondary imperfective verbs.  Secondary imperfectivization
%    usually involves the addition of the suffix -iv before the <base vocal>
%    _a.  In I_BASE* verbs it often involves jotation (a kind of
%    palatalization) with or without the addition of -iv.   It may
%    also entail vowel alternations.
%    It can be seen, therefore, that the hierarchy of bases not only
%    gives information about the shape of bases/stems for inflection
%    but also on the shape of the bases/stems to be derived from a
%    lexeme.  This potential information is used in the formation
%    of new lexemes.
%
% 7) A hierarchy of consonantal alternations. This provides the
%    different grades of consonant which may occur in different
%    base/stem types as defined by the hierarchy of bases.
%
% 8) Some (idiosyncratic) vowel alternations.
%
% 9) Closing declarations.
%
% The @ symbol is used together with ' to indicate softening
% (palatalization).  In the hierarchy of consonantal alternations
% the combination \^ is used for the class of labials to indicate
% the concatenation of the soft labial plus a soft l when the labial
% is the jotated grade.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                           %
%     WORD CLASS HIERARCHY                                                  %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 

WORD:
    <> ==  
    <gloss> == "<stem gloss>".

VERB:
    <> ==  WORD
    <syn cat> == v
    <syn aspect> == "<mor aspect>"
    <mor aspect> == "<base aspect>"
    <mor> == CONJ:<"<base conjugation>"> 
    <mor pres> == PRESENT:<"<mor aspect>">
    <mor fut> == FUTURE:<"<mor aspect>">.

REFL_VERB:
    <> == VERB
    <mor> == VERB REFLEXIVE_SUFFIX:<>
    <mor aspect> == VERB.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                             %
%     SWITCHES                                                                %
%                                                                             %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

CONJ:
    <first> == V_I:<>
    <second> == V_II:<>.

FUTURE:
    <perf> == CONJ:<"<base conjugation>">
    <impf> == "Bud'ot:<mor fut>" "<mor inf>".

PRESENT:
    <perf> == undefined
    <impf> == CONJ:<"<base conjugation>">.

MASC_PAST:
    <> == MOR_VERB:<past sg masc>
    <consonant> == "<stem 1 b>"
    <velar> == "<stem 1 b>".

INFINITIVE:
     <> == "<stem 1>" _t'
     <vowel velar> == "<stem 1>" _ch'
     <consonant> == "<stem 1>" _t'i
     <consonant vowel base> == <vowel>. %for past' etc.
JOT:
    <consonant> ==
    <vowel> == _j.

REFLEXIVE_SUFFIX:
    <> == SUFFIX_S'A:<"<mor aspect>">
    <past> == SUFFIX_S'
    <past sg masc> == SUFFIX_S'A   
    <inf> == 
       WHICH_SUFFIX:<"<base final 1>" "<base final 1 b>" "<base stress past>">
    <vowel> == .

WHICH_SUFFIX:
    <> == SUFFIX_S'A
    <consonant> == SUFFIX_S'
    <consonant vowel base> == SUFFIX_S'A.

SUFFIX_S':
    <> == _s'.

SUFFIX_S'A:
    <> == SUFFIX_S' _a
    <impf pres sg 1> == SUFFIX_S'
    <impf pres pl 2> == SUFFIX_S'
    <perf fut> == <impf pres>
    <perf pres> == 
    <impf fut> ==  .

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                         %
%       VERBAL INFLECTION                                                 %
%                                                                         %
%                                                                         %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 

MOR_VERB: 
    <inf> == INFINITIVE:<"<base final 1>" "<base final 1 b>" 
                                                 "<base stress past>" > 
    <fut> == FUTURE:<"<mor aspect>">
    <pres> == PRESENT:<"<mor aspect>">
    <sg 1> == "<stem 2 a>" JOT:<"<base final 2>"> _u
    <sg 2> == "<stem 2>" JOT:<"<base final 2>"> "<mor vowel>" _sh
    <sg 3> == "<stem 2>" JOT:<"<base final 2>"> "<mor vowel>" _t
    <pl 1> == "<stem 2>" JOT:<"<base final 2>"> "<mor vowel>" _m
    <pl 2> == "<stem 2>" JOT:<"<base final 2>"> "<mor vowel>" _te
    <past> == "<stem 1 b>" _l' PRED:<>
    <past sg> == "<stem 1 b>" _l PRED:<>.

V_I:
    <> == MOR_VERB
    <vowel> == _o
    <pl 3> == <sg 1> _t
    <past sg masc> == MASC_PAST:<"<base final 1 b>">.

V_II:
    <> == MOR_VERB
    <vowel> == _i
    <pl 3> == "<stem 2>" _at.

PRED:
    <> ==
    <fem> == _a
    <neut> == _o
    <pl> == _i. 

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                         %
%        HIERARCHY OF STEMS                                               %
%                                                                         %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 

STEM:
    <> == VERB
    <stem> == "<base>"
    <stem in> == v_ "<stem>" 
    <stem out> == vi_ "<stem>"
    <stem out2> == iz_ "<stem>"
    <stem out3> == izo_ "<stem>"
    <stem away> == ot_ "<stem>"
    <stem toward> == pod_ "<stem>"
    <stem through> == pro_ "<stem>"
    <stem upward> == vz_ "<stem>"
    <stem complete> == do_ "<stem>"
    <stem start> == za_ "<stem>"
    <stem on> ==  na_ "<stem>"
    <stem again> == pere_ "<stem>"
    <stem across> == pere_ "<stem>"
    <stem excess> == pere_ "<stem>"
    <stem partial> == po_ "<stem>"
    <stem arrival> == pr'i_ "<stem>"
    <stem thorough> == raz_ "<stem>"
    <stem with> == s_ "<stem>"
    <stem over> == nad_ "<stem>".

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                         %
%        HIERARCHY OF BASES                                               %
%                                                                         %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 

BASE_1:
    <> == STEM
    <base> == "<root>"
    <base aspect> == impf
    <base conjugation> == first
    <base final> == "<base final v>"
    <base final c> == "<root final>"
    <base final v> == "<base vocal>"
    <base final v c v> ==  _iv <base vocal>
    <base 1> == "<base>" "<base final c>" "<base final>"
    <base 2> == <base 1>
    <base final 1> == vowel
    <base final 2> == <base final 1>
    <base habitual> == "<base 1 v c v>"
    <base habitual aspect> == impf
    <base habitual final> == vowel
    <base habitual conjugation> == first
    <base vocal> == _a.

BASE_2:
    <> == BASE_1
    <base vocal> == _e.

BASE_3:
    <> == BASE_1
    <base 1> == BASE_1:<base 1 v c v>
    <base final v c v> == _ov "BASE_1:<base final>"
    <base final v> == _u.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                           %
%   CONSONANTAL BASES (i.e. consonant occurs before conjugation theme vowel)%
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

CONSONANTAL:
    <> == BASE_1
    <base all> == "<root 2>" "<root final>"
    <base 2> == "<base all soft>"
    <base final 2> == consonant.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                           %
%   CONSONANTAL BASES FOR THE SECOND CONJUGATION                            %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

I_BASEi:
    <> == CONSONANTAL
    <base conjugation> == second
    <base vocal> == _i
    <base 1> == BASE_1:<base 1 soft>
    <base 2 a> == "<base all jotated>"
    <base habitual> == BASE_1:<base 1 v c v>
    <base habitual bare_jotation> == BASE_1:<base 1 v jot>
    <base habitual aspect> == BASE_1
    <base habitual final> == BASE_1
    <base habitual conjugation> == BASE_1
    <base final c v> == "<root final jotated>"
    <base v c v> == "<root low>"
    <base final v jot> == BASE_1:<base vocal>.

I_BASEe:
    <> == I_BASEi
    <base vocal> == _e.

I_BASEja:
    <> == I_BASEi
    <base vocal> == _a.

I_BASEa:
    <> == I_BASEja
    <base 1> == BASE_1:<base 1 0>.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                           %
%   CONSONANTAL BASES FOR THE FIRST CONJUGATION                             %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

O_BASE_5:
    <> == CONSONANTAL
    <base 2 a> == "<base all 0>".

O_BASE_4:
    <> == O_BASE_5
    <base all> == "<root 2>" "<root final 0>" "<base final c>"
    <base 1> == <base all 0> _u
    <base final c> == N:<>
    <base aspect> == perf
    <base final 1> == _u
    <base 1 v c v> == "<root 2>" "<root final 0>" <base final v c v>.


O_BASE_5t'i: %nest'i etc.
    <> == O_BASE_5
    <base 1> == "<base all 0 spirant>"
    <base final 1> == consonant.

O_BASE_5CPAST: %vest'i
    <> == O_BASE_5t'i
    <base 1 b> == "<root>"
    <base final 1 b> == vowel.

O_BASE_5CT': % past' sest'
    <> == O_BASE_5CPAST
    <base stress past> == base.

O_BASE_5velar:
    <> == O_BASE_5
    <base 1> == "<root front>"
    <base 1 b> == "<root>" "<root final 0>"
    <base final 1 b> == velar.

O_BASE_6:
    <> == O_BASE_5
    <base 2> == <base all jotated>.

O_BASE_6a:
    <> == O_BASE_6
    <base vocal> == _o.

O_BASE_5r:
    <> == O_BASE_5
    <base vocal> == _e
    <base 1 b> == O_BASE_5t'i
    <base final 1 b> == O_BASE_5t'i.

O_BASE_7:
    <> == O_BASE_4
    <base 1> == BASE_1:<base 1 v>
    <base 1 v c v> == 
    "<root>" "<root final>" _i "<base final c 0>" "<base final v>"
    <base aspect> == BASE_1.

O_BASE_8:
    <> == O_BASE_7
    <base 1> == "<root 0>" "<base final>"
    <base final v> == "<root final>"
    <base final v c v> == BASE_1
    <base final c> == V:<>.

O_BASE_9:
    <> == O_BASE_8
    <base final c> == _j
    <base final v> == _i
    <base final v c v> == BASE_1.

O_BASE_10:
    <> == O_BASE_9
    <base 2> == "<root>" "<base final c>".

O_BASE_11:
    <> == O_BASE_7
    <base all> == "<root 2>" <base final c>
    <base 1> == "<root 0>" "<root final>" <base final v>
    <base final> == BASE_1
    <base final c> == "<root final>"
    <base final 2> == consonant
    <base 1 v c v> == "<root 0>" @' _i "<root final 0>" <base vocal>.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                           %
%   CONSONANTAL ALTERNATIONS                                                %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

CONS:
    <> == "<root final 0>"
    <type> == c
    <soft> == "<base final c 0>" @'
    <jotated> == "<base final c soft>".

LABIAL:
    <> == CONS
    <jotated> == "<base final c soft>" \^l@'.

P:
    <> == LABIAL
    <0> == _p.

B:
    <> == LABIAL
    <0> == _b.

M:
    <> == LABIAL
    <0> == _m.

F:
    <> == LABIAL
    <0> == _f.

V:
    <> == LABIAL
    <0> == _v.

T:
    <> == CONS
    <0> == _t
    <0 spirant> == _s
    <jotated> == _ch'.

T2:
    <> == T
    <jotated> == S T.

D:
    <> == CONS
    <0> == _d
    <0 spirant> == _s
    <jotated> == _zh
    <jotated jot d2> == D2:<jotated>. %_zhd

D2:
    <> == D
    <jotated> == D D:<0>.

N:
    <> == CONS
    <0> == _n.

R:
    <> == CONS
    <0> == _r.

S:
    <> == CONS
    <0> == _s
    <jotated> == _sh.

Z:
    <> == CONS
    <0> == _z
    <jotated> == _zh.

L:
    <> == CONS
    <0> == _l.

% Velars

K:
    <>  == CONS
    <0> == _k
    <soft> == _ch'.

G:
    <> == CONS
    <0> == _g
    <soft> == _zh.

X:
    <> == CONS
    <0> == _x
    <soft> == _sh.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                           %
%   VOWEL ALTERNATIONS                                                      %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

ABLAUT:
    <> == _o
    <0> ==
    <front> == _e
    <low> == _a.

ABLAUT_1:
    <> == ABLAUT
    <2> == ABLAUT:<>
    <2 0> == ABLAUT:<>.

ABLAUT_2:
    <> == ABLAUT
    <2> == ABLAUT:<front>.

ABLAUT_3:
    <> == ABLAUT
    <2> == ABLAUT:<low>
    <2 derived> == ABLAUT:<>. %for skoch'it'

ABLAUT_4:
    <> == @\' ABLAUT
    <2> == ABLAUT:<0>
    <2 0 spirant> == ABLAUT:<front>.

ABLAUT_5:
    <> == ABLAUT_2
    <2 0> == ABLAUT:<>.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Some example theorems:
% 
% P'isat':
%   <gloss> = to write
%   <mor inf> = p'i _s _a _t'
%   <mor fut sg 1> = bu _d _u p'i _s _a _t'
%   <mor fut sg 2> = bu _d @' _o _sh p'i _s _a _t'
%   <mor fut sg 3> = bu _d @' _o _t p'i _s _a _t'
%   <mor fut pl 1> = bu _d @' _o _m p'i _s _a _t'
%   <mor fut pl 2> = bu _d @' _o _te p'i _s _a _t'
%   <mor fut pl 3> = bu _d _u _t p'i _s _a _t'
%   <mor pres sg 1> = p'i _sh _u
%   <mor pres sg 2> = p'i _sh _o _sh
%   <mor pres sg 3> = p'i _sh _o _t
%   <mor pres pl 1> = p'i _sh _o _m
%   <mor pres pl 2> = p'i _sh _o _te
%   <mor pres pl 3> = p'i _sh _u _t
%   <mor past sg fem> = p'i _s _a _l _a
%   <mor past sg masc> = p'i _s _a _l
%   <mor past sg neut> = p'i _s _a _l _o
%   <mor past pl> = p'i _s _a _l' _i
%   <syn aspect> = impf.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % 
%                                                                           %
%   CLOSING DECLARATIONS                                                    %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

#show
    <gloss>
    <mor  inf>
    <mor fut sg 1>
    <mor fut sg 2>
    <mor fut sg 3>
    <mor fut pl 1>
    <mor fut pl 2>
    <mor fut pl 3>
    <mor  pres sg 1>
    <mor  pres sg 2>
    <mor  pres sg 3>
    <mor  pres pl 1>
    <mor  pres pl 2>
    <mor  pres pl 3>
    <mor  past sg fem>
    <mor  past sg masc>
    <mor  past sg neut>
    <mor  past pl>
    <syn aspect>.

#hide
    ABLAUT ABLAUT_1 ABLAUT_2 ABLAUT_3 ABLAUT_4 ABLAUT_5 ASPECT B BASE_1
    BASE_2 BASE_3 CONJ CONS CONSONANTAL D D2 F FUTURE G INFINITIVE
    I_BASEa I_BASEe I_BASEi I_BASEja JOT K L LABIAL M MASC_PAST MOR_VERB
    N O_BASE_10 O_BASE_11 O_BASE_4 O_BASE_5 O_BASE_5CPAST O_BASE_5CT'
    O_BASE_5r O_BASE_5t'i O_BASE_5velar O_BASE_6 O_BASE_6a O_BASE_6b
    O_BASE_7 O_BASE_8 O_BASE_9 P PRED PRESENT R REFLEXIVE_SUFFIX
    REFL_VERB S SL STEM SUFFIX_S' SUFFIX_S'A T T2 V VERB V_I V_II
    WHICH_SUFFIX WORD X Z.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% The next line is the Revision Control System Archive Id: do not delete it.
% $Id: archive.dtr,v 1.1 1997/04/09 20:40:33 root Exp $