% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            numerals.dtr                                             %
% Purpose:         map number-language pairs into numerals                  %
% Authors:         Lynne Cahill & Gerald Gazdar, 1st January 1996           %
% Email:           lynneca@cogs.sussex.ac.uk, geraldg@cogs.sussex.ac.uk     %
% Address:         COGS, Sussex University, Brighton BN1 9QH, UK            %
% Documentation:   see paper noted below                                    %
% Related files:   numerale.dtr                                             %
% Version:         2.01                                                     %
%                                                                           %
%      Copyright (c) University of Sussex 1996.  All rights reserved.       %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% This fragment is that discussed in Lynne Cahill & Gerald Gazdar (1996)
% "A lexical analysis of numeral expressions in three related languages",
% unpublished manuscript, University of Sussex, available by anonymous
% FTP from ftp.cogs.sussex.ac.uk in /pub/nlp/POLYLEX/papers/numerals.ps.

# atom A D E G I M V 'u:' 'i:' '3:' 'O:' T 'y:' O 'e:' 'A:' U '|:'.

# vars $v1: 1 2 3 4 5 6 7 8 9.
# vars $v2:   2 3 4 5 6 7 8 9.
# vars $v3:     3 4 5 6 7 8 9.

% Variable $L ranges over the language identification atoms:

# vars $L:  D E G.

% Set node L to the desired language identification atom here:

L:<> == G.  % or D or E

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% The Numeral node finds a value for the <phn form> path by packaging up the
% language identification atom with a linear representation of the meaning
% of the numeral in a path and handing it over to the Syntax node for
% evaluation:

Numeral:
    <val> == 0
    <phn form> == "Syntax:<L m "<val m>"
                             c "<val c>"
                             x "<val x>"
                             i "<val i>">".

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% The Syntax node examines the initial attribute to ascertain the identity
% of the language.  If the language is Dutch, then the attribute is
% simply removed and the semantic representation is processed by the
% Syntax node itself.  If the language is English, then the semantic
% representation is passed over to Syntax/E for processing; if the language
% is German, then the semantic representation is passed over to Syntax/G.
% Syntax, Syntax/G and Syntax/E recursively transduce the semantic
% representation into a syntactic representation that consists of a sequence
% of roots.  Each such root is then mapped to a phonological representation
% via the Morphology node (or Morphology/E).

Syntax:
    <D> == <>
    <G> == "Syntax/G:<>"
    <E> == "Syntax/E:<>"

    <x 0>               == "<>"
    <x $v2>             == "<>"
                           Morphology:<conj>
                           Morphology
    <x $v2 i 0>         == Morphology
    <c 0>               == "<>"
    <c $v1>             == Morphology
                           "<>"
    <c $v1 x 0 i 0>     == Morphology
    <m 0>               == "<>"
    <m $v1>             == Morphology
                           "<>"
    <m $v1 c 0>         == Morphology
                           Morphology:<conj>
                           "<>"
    <m $v1 c 0 x 0 i 0> == Morphology
    <m 0 c 0 x 0 i 0>   == Morphology:<zero>
    <>                  == Morphology.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% For the most part, the Morphology node simply maps the individual components
% of the syntactic representation to the corresponding multilingual phonology
% nodes which determine the phonology of the roots from the identity of the
% language.

Morphology:
    <conj>    == "PhonCnj:<L phn root>"
    <zero>    == "PhonNil:<L phn root>"
    <i 0>     ==
    <i 1>     == "Phon001:<L phn root>"
    <i 2>     == "Phon002:<L phn root>"
    <i 3>     == "Phon003:<L phn root>"
    <i 4>     == "Phon004:<L phn root>"
    <i 5>     == "Phon005:<L phn root>"
    <i 6>     == "Phon006:<L phn root>"
    <i 7>     == "Phon007:<L phn root>"
    <i 8>     == "Phon008:<L phn root>"
    <i 9>     == "Phon009:<L phn root>"
    <x 1 i 0> == "Phon010:<L phn root>"
    <x 1 i 1> == "Phon011:<L phn root>"
    <x 1 i 2> == "Phon012:<L phn root>"

% The next two equations have the effect of selecting the variant roots
% required in examples such as "thirteen" (3 + 10 ==> "thir" ^ "teen")
% and "siebzig" (7 * 10 ==> "sieb" ^ "zig"):

    <x 1 i $v3> == <i $v3 n_x> "PhonA10:<L phn root>"
    <x $v2>     == <i $v2 n_x> "PhonB10:<L phn root>"

% The final set of equations deals with the realization of the hundreds and
% thousands components:

    <c>   == <i> "Phon100:<L phn root>"
    <c 1> ==     "Phon100:<L phn root>"
    <m>   == <i> "Phon000:<L phn root>".

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Numbers like 23 should be realized as "twenty three" in English, not as
% "three and twenty" as they would be if English followed exactly the pattern
% of Dutch and German.  And numbers like 302 should be realized as "three
% hundred and two", not as "three hundred two" as they are in Dutch and
% German.

Syntax/E:
    <> == Syntax
    <x $v2> == Morphology <>
    <c $v1> == Morphology/E Morphology:<conj> <>
    <c $v1 x 0 i 0> == Morphology/E.

% The number 100 should be realized as "one hundred" in English, not as
% "hundred" as it would be if English followed exactly the pattern of
% Dutch and German.

Morphology/E:
    <> == Morphology
    <c 1> == <i 1> Morphology.

% The number 30 in German is `dreissig', /draisIx/ and not `dreizig',
% /draitsIx/.

Syntax/G:
    <> == Syntax
    <x 0 i $v1> == <i $v1 n_i>
    <x 3> == "<>" Morphology:<conj> Morphology/G
    <x 3 i 0> == Morphology/G.

Morphology/G:
    <> == Morphology
    <x 3> == <i 3> "PhonC10:<G phn root>".

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% The phonology nodes have been kept simple.  No distinction is drawn
% between roots and words: the only distinctions are those between
% Syllable, Disyllable and Trisyllable.  And there is no treatment of
% stress.

Null:
    <> == .

Syllable:
    <> == Null
    <$L> == "<M>"

    <M phn root>  == "<L phn syll>"
    <M phn syll>  == "<L phn onset>"  "<L phn rhyme>"
    <M phn rhyme> == "<L phn peak>"   "<L phn coda>"
    <M phn coda>  == "<L phn body>"   "<L phn tail>".

% Note that initial and final syllables within roots are not given any
% internal analysis at present, though they really need to be (see the
% redundant specification of final syllables given in the Phon100 and
% Phon000 nodes).

Disyllable:
    <> == Syllable
    <M phn root>  == "<L phn syll>" "<L phn final>".

Trisyllable:
    <> == Syllable
    <M phn root>  == "<L phn initial>" "<L phn syll>" "<L phn final>".

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% The multilingual root phonology nodes given below are all defined at the
% level of the segment.  But they could be much more effectively stated at
% a featural level -- especially the vowels.

PhonCnj:
    <> == Syllable
    <M phn body> == n

    <D phn peak> == E

    <E phn peak> == '{'
    <E phn tail> == d

    <G phn peak> == U
    <G phn tail> == t.

PhonNil:
    <> == Syllable
    <M phn onset> == n
    <M phn peak> == U
    <M phn body> == l

    <E phn peak> == I.

Phon001:
    <> == Syllable
    <M phn body> == n

    <D phn peak> == 'e:'

    <E phn onset> == w
    <E phn peak> == V

    <G phn peak> == a i
    <G phn tail n_i> == s.

Phon002:
    <> == Syllable
    <M phn body n_x> == n

    <D phn onset> == t w
    <D phn peak> == 'e:'
    <D phn peak n_x> == I

    <E phn onset> == t
    <E phn onset n_x> == t w
    <E phn peak> == 'u:'
    <E phn peak n_x> == E

    <G phn onset> == t s v
    <G phn peak> == a i
    <G phn peak n_x> == a.

Phon003:
    <> == Syllable
    <M phn onset> == d r
    <M phn peak> == 'i:'

    <D phn peak> == 'i:'

    <E phn onset> == T r
    <E phn onset n_x> == T
    <E phn peak n_x> == '3:'

    <G phn peak> == a i.

Phon004:
    <> == Syllable
    <M phn onset> == f
    <M phn peak> == 'i:'
    <M phn body> == r

    <D phn onset> == v

    <E phn peak> == 'O:'.

Phon005:
    <> == Syllable
    <M phn onset> == f
    <M phn tail> == f

    <D phn onset> == v
    <D phn peak> == E I

    <E phn peak n_x> == I
    <E phn peak> == a I
    <E phn tail n_x> == f
    <E phn tail> == v

    <G phn peak> == 'y:'
    <G phn body> == n.

Phon006:
    <> == Syllable
    <M phn onset> == z
    <M phn peak> == E
    <M phn body> == k
    <M phn tail> == s

    <D phn body> == Null

    <E phn onset> == s
    <E phn peak> == I.

Phon007:
    <> == Disyllable
    <M phn onset> == z
    <M phn tail> == v
    <M phn final> == @ n

    <D phn peak> == 'e:'
    <D phn final> == @

    <E phn onset> == s
    <E phn peak> == E

    <G phn peak> == 'i:'
    <G phn tail> == b
    <G phn final n_x> == Null.

Phon008:
    <> == Syllable
    <M phn body> == x
    <M phn tail> == t

    <D phn peak> == A

    <E phn peak> == e I
    <E phn body> == Null

    <G phn peak> == 'A:'.

Phon009:
    <> == Syllable
    <M phn onset> == n
    <M phn body> == n

    <D> == Disyllable:<M>
    <D phn onset> == <M phn onset>  % This line cannot be omitted!
    <D phn peak> == 'e:'
    <D phn final> == g @

    <E phn peak> == a I

    <G phn peak> == O y.

Phon010:
    <> == Syllable
    <M phn onset> == t
    <M phn body> == n
    <M phn peak> == 'i:'

    <E phn peak> == E

    <G phn onset> == t s
    <G phn peak> == 'e:'.

PhonA10:
    <> == Phon010

    <E> == Phon010:<M>.

PhonB10:
    <> == Syllable
    <M phn onset> == Phon010
    <M phn tail> == x

    <D phn peak> == @

    <E phn peak> == 'i:'
    <E phn tail> == Null

    <G phn onset> == Phon010
    <G phn peak> == I.

% Deviant form of -zig suffix for German `dreissig'.

PhonC10:
    <> == PhonB10
    <G phn onset> == s.

Phon011:
    <> == Syllable
    <M phn peak> == E
    <M phn body> == l
    <M phn tail> == f

    <E> == Trisyllable:<M>
    <E phn initial> == @
    <E phn onset> == l
    <E phn peak> == <M phn peak> % This line cannot be omitted!
    <E phn final> == v @ n.

Phon012:
    <> == Syllable
    <M phn onset> == t w
    <M phn body> == l
    <M phn tail> == f

    <D phn peak> == 'a:'

    <E phn peak> == E
    <E phn tail> == v

    <G phn onset> == Phon002
    <G phn peak> == '|:'.

Phon100:
    <> == Disyllable
    <M phn onset> == h
    <M phn tail> == n
    <M phn final> == d @ r t

    <D phn peak> == O

    <E phn peak> == V
    <E phn final> == d r E d

    <G phn peak> == U.

Phon000:
    <> == Disyllable
    <M phn final> == z @ n t

    <D phn onset> == d
    <D phn peak> == / I

    <E phn onset> == T
    <E phn peak> == a U
    <E phn final> == z @ n d

    <G phn onset> == t
    <G phn peak> == a u.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Test nodes:

Word_1:
    <> == Numeral
    <val i> == 1.

Word_2:
    <> == Numeral
    <val i> == 2.

Word_3:
    <> == Numeral
    <val i> == 3.

Word_4:
    <> == Numeral
    <val i> == 4.

Word_5:
    <> == Numeral
    <val i> == 5.

Word_6:
    <> == Numeral
    <val i> == 6.

Word_7:
    <> == Numeral
    <val i> == 7.

Word_8:
    <> == Numeral
    <val i> == 8.

Word_9:
    <> == Numeral
    <val i> == 9.

Word_10:
    <> == Numeral
    <val x> == 1.

Word_11:
    <> == Numeral
    <val i> == 1
    <val x> == 1.

Word_12:
    <> == Numeral
    <val i> == 2
    <val x> == 1.

Word_13:
    <> == Numeral
    <val i> == 3
    <val x> == 1.

Word_14:
    <> == Numeral
    <val i> == 4
    <val x> == 1.

Word_15:
    <> == Numeral
    <val i> == 5
    <val x> == 1.

Word_16:
    <> == Numeral
    <val i> == 6
    <val x> == 1.

Word_17:
    <> == Numeral
    <val i> == 7
    <val x> == 1.

Word_18:
    <> == Numeral
    <val i> == 8
    <val x> == 1.

Word_19:
    <> == Numeral
    <val i> == 9
    <val x> == 1.

Word_20:
    <> == Numeral
    <val x> == 2.

Word_21:
    <> == Numeral
    <val i> == 1
    <val x> == 2.

Word_31:
    <> == Numeral
    <val i> == 1
    <val x> == 3.

Word_41:
    <> == Numeral
    <val i> == 1
    <val x> == 4.

Word_51:
    <> == Numeral
    <val i> == 1
    <val x> == 5.

Word_61:
    <> == Numeral
    <val i> == 1
    <val x> == 6.

Word_71:
    <> == Numeral
    <val i> == 1
    <val x> == 7.

Word_81:
    <> == Numeral
    <val i> == 1
    <val x> == 8.

Word_91:
    <> == Numeral
    <val i> == 1
    <val x> == 9.

Word_92:
    <> == Numeral
    <val i> == 2
    <val x> == 9.

Word_93:
    <> == Numeral
    <val i> == 3
    <val x> == 9.

Word_94:
    <> == Numeral
    <val i> == 4
    <val x> == 9.

Word_95:
    <> == Numeral
    <val i> == 5
    <val x> == 9.

Word_96:
    <> == Numeral
    <val i> == 6
    <val x> == 9.

Word_97:
    <> == Numeral
    <val i> == 7
    <val x> == 9.

Word_98:
    <> == Numeral
    <val i> == 8
    <val x> == 9.

Word_99:
    <> == Numeral
    <val i> == 9
    <val x> == 9.

Word_100:
    <> == Numeral
    <val c> == 1.

Word_101:
    <> == Numeral
    <val c> == 1
    <val i> == 1.

Word_121:
    <> == Numeral
    <val c> == 1
    <val x> == 2
    <val i> == 1.

Word_221:
    <> == Numeral
    <val c> == 2
    <val x> == 2
    <val i> == 1.

Word_521:
    <> == Numeral
    <val c> == 5
    <val x> == 2
    <val i> == 1.

Word_5031:
    <> == Numeral
    <val m> == 5
    <val x> == 3
    <val i> == 1.

Word_2345:
    <> == Numeral
    <val m> == 2
    <val c> == 3
    <val x> == 4
    <val i> == 5.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# hide Numeral Syntax Morphology Phon001 Phon002 Phon003 Phon004 Phon005
       Phon006 Phon007 Phon008 Phon009 Phon010 PhonA10 PhonB10 Phon011
       Phon012 Phon100 Phon000 PhonCnj  PhnNil Null Syllable Disyllable
       Trisyllable L PhonC10                       Syntax/E Morphology/E.

# show
    <phn form>.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% The next line is the Revision Control System Id: do not delete it.
% $Id: archive.dtr,v 1.1 1997/04/09 20:40:33 root Exp $