% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            ilex.dtr                                                 %
% Purpose:         integrated lexical generalisations                       %
% Author:          Dafydd Gibbon, 13 February 1990                          %
% Email:           gibbon@spectrum.uni-bielefeld.de                         %
% Address:         Univ. Bielefeld, P 100131, D-33501, Bielefeld, Germany   %
% Documentation:   see paper cited below                                    %
% Version:         2.01                                                     %
%                                                                           %
%      Copyright (c) Dafydd Gibbon, 1990.  All rights reserved.             %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Dafydd Gibbon (1991) "ILEX: a linguistic approach to computational lexica"
% in Ursula Klenk, ed., Computatio Linguae: Aufsaetze Zur algorithmischen
% und quantitativen Analyse der Sprache, Zetschrift fuer Dialektologie und
% Linguistik, Beiheft 7, 32-53.

% In this version of the file "ae", "oe" and "ue" represent umlauted "a",
% "o", and "u", respectively.

% Integrated lexical generalisations in DATR

% The lexicon model ILEX is based on generalisations about the
% relationships between lexemes and templates; it is related to
% the three classical models of lexical structure (IA, IP, WP):

% Item and arrangement: Items are assigned to templates.

% Word and paradigm: Paradigm-like generalisations about words
%                    are formulated.

% Item and process:  Inter-domain ("level") dependencies are
%                    formulated, corresponding to the inter-
%                    domain processes of generative phonology.

% Generalisations are arranged in two dimensions, one ordered in
% terms of specificy and generality between lexemes and
% templates, and the other (implicitly) ordered in terms of
% constituency relations between templates.

% Dimension 1:

% INVENTORIES----Generalisation Scale-------->TEMPLATES
%   ------<context-free conditions on fillers>------>
%   <--"<context-sensitive conditions on fillers>"--

% Dimension 2:

% Constituency-based domains of generalisation:
% (1) Morphotactics (inflexion, compounding, derivation, root).
% (2) Morphophonemics & morphographemics: adaptation to
%     morphotactic contexts.
% (3) Phonological well-formedness conditions, systematic
%     phonetics.
% (4) Phonetics.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Inventory of lexical items

% Simplex lexical entries

Alter:
    <orth peak vowel> == A
    <orth peak sonor> == L
    <orth peak length> == long
    <orth coda> == T
    <orth appendix> == R
    <morph gender> == neut
    <> == Noun_1a.

Auge:
    <orth peak vowel> == A
    <orth peak sonor> == U
    <orth peak length> == long
    <orth coda> == G
    <morph gender> == neut
    <> == Noun_4a.

Auto:
    <orth peak vowel> == A
    <orth peak sonor> == U
    <orth peak length> == long
    <orth coda> == T
    <orth appendix> == O
    <> == Noun_5.

Bild:
    <orth onset cons> == B
    <orth peak vowel> == I
    <orth peak sonor> == L
    <orth peak length> == long
    <orth coda> == D
    <> == Noun_3.

Brief:
    <orth onset cons> == B
    <orth onset sonor> == R
    <orth peak vowel> == I
    <orth peak sonor> == E
    <orth peak length> == long
    <orth coda> == F
    <> == Noun_2.

Chor:
    <orth onset cons> == C
    <orth onset diacritic> == H
    <orth peak vowel> == O
    <orth peak length> == long
    <orth coda> == R
    <> == Noun_2.

Dose:
    <orth onset cons> == D
    <orth peak vowel> == O
    <orth peak length> == 
    <orth coda> == S
    <> == Noun_4a.

Floss:
    <orth onset cons> == F
    <orth onset sonor> == L
    <orth peak vowel> == O
    <orth peak length> == long
    <orth coda> == S
    <> == Noun_2.

Fluss:
    <orth onset cons> == F
    <orth onset sonor> == L
    <orth peak vowel> == U
    <orth coda> == S
    <> == Noun_2.

Frau:
    <orth onset cons> == F
    <orth onset sonor> == R
    <orth peak vowel> == A
    <orth peak sonor> == U
    <orth peak length> == long
    <> == Noun_4.

Hund:
    <orth onset cons> == H
    <orth peak vowel> == U
    <orth peak sonor> == N
    <orth peak length> == long
    <orth coda> == D
    <> == Noun_2a.

Kalb:
    <orth onset cons> == K
    <orth peak vowel> == A
    <orth peak sonor> == L
    <orth peak length> == long
    <orth coda> == B
    <> == Noun_3.

Liebe:
    <orth onset cons> == L
    <orth peak vowel> == I
    <orth peak sonor> == E
    <orth peak length> == long
    <orth coda> == B
    <> == Noun_4a.

Mann:
    <orth onset cons> == M
    <orth peak vowel> == A
    <orth coda> == N
    <morph gender> == masc
    <> == Noun_3.

Mutter:
    <orth onset cons> == M
    <orth peak vowel> == U
    <orth coda> == T
    <orth appendix> == R
    <morph gender> == femn
    <> == Noun_1.

Oeffner:
    <orth peak vowel> == Oe
    <orth coda> == F
    <orth appendix> == N R
    <> == Noun_1.

Person:
    <orth onset cons> == P
    <orth peak vowel> == E
    <orth peak sonor> == R
    <orth appendix> == S O N:<orth>
    <> == Noun_4.

Sau:
    <orth onset cons> == S
    <orth peak vowel> == A
    <orth peak sonor> == U
    <orth peak length> == long
    <morph gender> == femn
    <> == Noun_2.

Stadt:
    <orth onset sib> == S
    <orth onset cons> == T
    <orth peak vowel> == A
    <orth coda> == d t
    <morph gender> == femn
    <> == Noun_2.

Tochter:
    <orth onset cons> == T
    <orth peak vowel> == O
    <orth peak sonor> == C H
    <orth peak length> == long
    <> == Mutter.

Weib:
    <orth onset cons> == W
    <orth peak vowel> == E
    <orth peak sonor> == I
    <orth peak length> == long
    <orth coda> == B
    <morph gender> == neut
    <> == Noun_3.

Wolf:
    <orth onset cons> == W
    <orth peak vowel> == O
    <orth peak sonor> == L
    <orth peak length> == long
    <orth coda> == F
    <> == Noun_2.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Complex lexical entries

Mannweib:
    <determinans> == "Mann:<>"
    <determinatum> == "Weib:<>"
    <> == Noun_Compound.

Mannalter:
    <determinans> == "Mann:<>"
    <determinatum> == "Alter:<>"
    <orth interfix> == genitive es
    <> == Noun_Compound.

Mannbild:
    <determinans> == "Mann:<>"
    <determinatum> == "Bild:<>"
    <orth interfix> == genitive
    <> == Noun_Compound.

Mannchor:
    <determinans> == "Mann:<>"
    <determinatum> == "Chor:<>"
    <orth interfix> == plural
    <> == Noun_Compound.

Frauchor:
    <determinans> == "Frau:<>"
    <> == Maennerchor.

Frauperson:
    <determinans> == "Frau:<>"
    <determinatum> == "Person:<>"
    <> == Noun_Compound_a.

Weibbild:
    <determinans> == "Weib:<>"
    <> == Mannsbild.

Liebebrief:
    <determinans> == "Liebe:<>"
    <determinatum> == "Brief:<>"
    <orth interfix> == genitive masc
    <> == Noun_Compound.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Noun subclasses

Noun_1a:
    <> == Noun_1                   % Kater
    <plural stem op> == .

Noun_1:
    <> == Noun
    <plural affix> == 
    <morph gender> == masc.        % Vater

Noun_2a:
    <> == Noun_2
    <plural stem op> == .          % Hund

Noun_2:
    <> == Noun
    <plural affix> == e
    <morph gender> == masc.        % Wolf

Noun_3:
    <> == Noun
    <plural affix> == er
    <morph gender> == neut.        % Lamm

Noun_4a:
    <> == Noun_4
    <orth appendix> == E
    <orth appendix plural> == N.

Noun_4:
    <> == Noun
    <plural affix> == en           % Katzen
    <plural stem op> == 
    <morph gender> == femn.

Noun_5:
    <> == Noun
    <plural affix> == genitive masc
    <plural stem op> == .

Noun_Compound_a:
    <> == Noun_Compound
    <orth interfix> == plural genitive masc.

Noun_Compound:
    <> == Noun
    <morph type> == compound
    <orth interfix> == .

Noun:
    <> == Morph_templates
    <sem> == concrete
    <syn cat> == noun
    <morph type> == simplex
    <morph case> == acc
    <morph number> == sing
    <morph gender> == neut
    <orth onset> == 
    <orth peak> == 
    <orth coda> == 
    <orth appendix> == 
    <orth peak length> == short
    <plural stem op> == umlaut.

% Lexeme templates

Morph_templates:
    <> == 
    <orth> == Orth_templates
    <phon> == Phon_templates.

Orth_templates:
    <> == 'dings'
    <orth> == <orth "<morph type>">
    <orth root> == "<orth onset sibil>"
                    "<orth onset cons>"
                    "<orth onset sonor>"
                    "<orth peak vowel>"
                    "<orth peak sonor>"
                    "<orth coda>"
                    "<orth appendix>"
    <orth simplex>  == "<orth root>" Suffix:<orth>
    <orth compound> == "<determinans orth "<orth interfix>" !>"
                        "<determinatum orth>".

Phon_templates:
    <> == 'in SAMPA notation:/diNs/'.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Morphotactic operation inventory

% Conditions for morphotactic operations

Suffix:
    <orth plural> == Infl:<orth "<plural affix>">
    <orth genitive> == <orth genitive "<morph gender>">
    <orth genitive neut> == <orth genitive masc>
    <orth genitive masc> == Infl
    <> == .

Infl:
    <> == 
    <orth e> == E
    <orth er> == E R
    <orth en> == E N <orth>
    <orth genitive> == S
    <orth genitive es> == E S.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Morphographemic inventory

A:
    <orth maj> == 'A'
    <orth peak vowel plural> == <orth "<plural stem op>">
    <orth umlaut> == Ae:<orth >
    <orth> == a.
Ae:
    <orth maj> == 'Ae'
    <orth> == 'ae'.
B:
    <orth maj> == 'B'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth > <orth >
    <orth> == b.
C:
    <orth maj> == 'C'
    <orth onset> == <orth> "<orth onset diacritic>"
    <orth> == c.
D:
    <orth maj> == 'D'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <> == d.
E:
    <orth maj> == 'E'
    <orth peak vowel> == <orth>
    <orth appendix plural> == 
    <orth> == e.
F:
    <orth maj> == 'F'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth> == f.
G:
    <orth maj> == 'G'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth> == g.
H:
    <orth maj> == 'H'
    <orth> == h.
I:
    <orth maj> == 'I'
    <orth peak vowel> == <orth>
    <orth> == i.
J:
    <orth maj> == 'J'
    <orth> == j.
K:
    <orth maj> == 'K'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth> == k.
L:
    <orth maj> == 'L'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth appendix> == e l
    <orth> == l.
M:
    <orth maj> == 'M'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth appendix> == e m
    <orth> == m.
N:
    <orth maj> == 'N'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth appendix> == e n
    <orth> == n.
O:
    <orth maj> == 'O'
    <orth peak vowel plural> == <orth "<plural stem op>">
    <orth umlaut> == Oe:<orth>
    <orth> == o.
Oe:
    <orth maj> == 'Oe'
    <orth> == 'oe'.
P:
    <orth maj> == 'P'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth> == p.
Q:
    <orth maj> == 'Q'
    <orth> == q.
R:
    <orth maj> == 'R'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth appendix> == e r
    <orth> == r.
S:
    <orth maj> == 'S'
    <orth coda> == <orth "<orth peak length>">
    <orth short plural> == <orth> <orth>
    <orth short> == <orth long>
    <orth long> == s s
    <orth> == s.
T:
    <orth maj> == 'T'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth> == t.
U:
    <orth maj> == 'U'
    <orth peak vowel plural> == <orth "<plural stem op>">
    <orth umlaut> == Ue:<orth>
    <orth> == u.
Ue:
    <orth maj> == 'Ue'
    <orth> == 'ue'.
V:
    <orth maj> == 'V'
    <orth> == v.
W:
    <orth maj> == 'W'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth> == w.
X:
    <orth maj> == 'X'
    <orth> == x.
Y:
    <orth maj> == 'Y'
    <orth> == y.
Z:
    <orth maj> == 'Z'
    <orth coda> == <orth "<orth peak length>">
    <orth short> == <orth> <orth>
    <orth> == z.

% The next line is the Revision Control System Id: do not delete it.
% $Id: archive.dtr,v 1.1 1997/04/09 20:40:33 root Exp $