% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            fldtest.dtr                                              %
% Purpose:         construction of feature-logic descriptions               %
% Author:          James Kilbury, 2 February 1993                           %
% Email:           kilbury@ling.uni-duesseldorf.de                          %
% Address:         U Drf, Universitaetsstr. 1, D-40225 Duesseldorf, Germany %
% Related files:   fldcons.dtr, fldtest1.dmp, fldtest2.dmp, englex2.dtr     %
% Version:         2.05 (21 September 1994)                                 %
%                                                                           %
%      Copyright (c) University of Duesseldorf 1994.  All rights reserved.  %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Call  cp([fldcons, fldpatr2, fldtest])  (PATR-II syntax) or
%       cp([fldcons, fldqpatr, fldtest])  (QPATR syntax)   to load,
%       inferences(10000)                 to set recursion depth, and then
%       A                                 to get the feature-structure
%                                         description defined by node A.
%
%       A:<*> =  < X a b c > = 1 .        PATR-II
%       A:<*> =  X / a / b / c *= 1 .     QPATR


% simple examples % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

A:
    <*> == FS:<a ^>                    % '*' designates the end of a path
    <a *> == FS:<b ^>                  % in a feature structure or DAG;
    <a b *> == FS:<c ^>                % expressions with FS, ATOM, and VAR
    <a b c *> == ATOM:<1 ^>.           % stipulate typing. '^' is a node
				       % that transduces attribute paths.

B:
    <*> == FS:<a c ^>
    <a *> == FS:<b ^>
    <a b *> == ATOM:<1 ^>
    <c *> == FS:<d e ^>
    <c d *> == ATOM:<2 ^>
    <c e *> == FS:<f ^>
    <c e f *> == ATOM:<3 ^>.


% examples with lists % % % % % % % % % % % % % % % % % % % % % % % % % % % %

C:
    <*> == FS:<fi re ^>
    <fi *> == ATOM:<a ^>
    <re *> == FS:<fi re ^>
    <re fi *> == ATOM:<b ^>
    <re re *> == ATOM:<nil ^>.

D:
    <*> == LIST                        % LIST:<> == FS:<fi re ^>.
    <fi *> == ATOM:<a ^>
    <re *> == LIST
    <re fi *> == ATOM:<b ^>
    <re re *> == ATOM:<nil ^>.

E:
    <*> == LIST
    <fi *> == LIST
    <fi fi *> == ATOM:<a ^>
    <fi re *> == ATOM:<nil ^>
    <re *> == LIST
    <re fi *> == LIST
    <re fi fi *> == ATOM:<b ^>
    <re fi re *> == ATOM:<nil ^>
    <re re *> == ATOM:<nil ^>.


% examples with reentrancy  % % % % % % % % % % % % % % % % % % % % % % % % %

F:
    <*> == LIST
    <fi *> == RP:<re fi * ^>           % First specify the reentrant paths
	      VAR:<^>                  % and then the type at the r. point.
    <re *> == LIST
    <re fi *> == VAR:<^>
    <re re *> == ATOM:<nil ^>.


G:    
    <*> == FS:<f g ^>
    <f *> == RP:<g f * ^>  
	     FS:<f h ^>
    <f f *> == ATOM:<a ^>
    <f h *> == VAR:<^>

    <g *> == FS:<f ^>                  % This should be eliminated to
    <g f *> == FS:<f h ^>              % avoid redundant formulas in the
    <g f f *> == ATOM:<a ^>            % feature-structure description.
    <g f h *> == VAR:<^>.              %
  
H:      
    <*> == FS:<f ^>                    % ONE possible solution for G:
    <f *> == RP:<g f * ^>              % only f is declared as being
	     FS:<f h ^>                % specified in H, since the path
    <f f *> == ATOM:<a ^>              % <g f> is already fully described
    <f h *> == VAR:<^>.                % with the reentrancy.


% examples with calls to other FS-nodes % % % % % % % % % % % % % % % % % % %

I:
    <*> == FS:<f ^>
    <f> == A:< |:<>  ||'  ~:< |:<> | > >.
%          A:< \\ >                      An alias for the eval. expressions
%                                        is desirable as 'syntactic sugar'.

J:
    <*> == FS:<f g ^>
    <f> == A:< |:<>  ||'  ~:< |:<> | > >
    <g> == A:< |:<>  ||'  ~:< |:<> | > >.

K:
    <*> == FS:<f g h ^>
    <f> == A:< |:<> ||' ~:< |:<> | > >
    <g> == ATOM:<0 ^>
    <h> == B:< |:<>  ||'  ~:< |:<> | > >.

% multiple embedding of calls to other FS-nodes % % % % % % % % % % % % % % %

L:
    <*> == FS:<f ^>
    <f> == M:< |:<>  ||'  ~:< |:<> | > >.

M:
    <*> == FS:<g ^>
    <g> == N:< |:<>  ||'  ~:< |:<> | > >.

N:
    <*> == ATOM:<1 ^>.

%___________________

P:
    <*> == FS:<f ^>
    <f> == Q:< |:<>  ||'  ~:< |:<> | > >.

Q:
    <*> == FS:<g ^>
    <g> == R:< |:<>  ||'  ~:< |:<> | > >.

R:
    <*> == FS:<h ^>
    <h *> == ATOM:<1 ^>.

%___________________

S:
    <*> == FS:<m n ^>
    <m> == K:< |:<>  ||'  ~:< |:<> | > >
    <n> == P:< |:<>  ||'  ~:< |:<> | > >.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# show <*>.

# hide
    FS LIST ATOM VAR RP FS_Path FL_Fmlas Path_Expr FL_Path FL_Path_Rest
    ^ ~ | || ||| |' ||' |||' Bounded$ PRev$ PCutoff$ PCut$
    Anon_Var& Variable& Conjunction& Value_at_Path& Reentrancy& 
    FS_at_Path& Path_Connective& LBracket& RBracket&.

% The next line is the Revision Control System Id: do not delete it.
% $Id: archive.dtr,v 1.1 1997/04/09 20:40:33 root Exp $