% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            eng_fren.dtr                                             %
% Purpose:         fragment of a bilingual English/French lexicon           %
% Authors:         Cecile Fabre & Anne LeDraoulec, 27 August 1992           %
% Version:         1.01                                                     %
%      Copyright (c) University of Paris VII.  All rights reserved.         %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% French and English have much in common syntactically.  In constructing
% a bilingual lexicon for French and English, it makes sense to try and
% extract the commonalities and state them in a way that abstracts from
% the particularities of each language (e.g., the form of a preposition).

PREP:
        <about1 eng> == about
        <about1 fre> == a
        <about2 eng> == about
        <about2 fre> == de
        <on eng> == on
        <on fre> == sur
        <none eng> == 
        <none fre> == de
        <to eng> == to
        <to fre> == a.

THAT:
        <that1 eng> == that sentence
        <that1 fre> == que phrase
        <that2 eng> == that sentence
        <that2 fre> == "<args rest first prep>" ce que phrase
        <that3 eng> == that sentence
        <that4 fre> == que phrase
        <that5 fre> == "<args rest first prep>" ce que phrase
        <that6 eng> == that sentence
        <that6 fre> == "<args rest rest first prep>" ce que phrase.

INF:
        <inf1 eng> == to infinitive
        <inf1 fre> == de infinitif
        <inf2 eng> == infinitive
        <inf2 fre> == de infinitif
        <inf3 eng> == infinitive
        <inf3 fre> == infinitif
        <inf4 eng> == to infinitive
        <inf4 fre> == infinitif
        <inf5 eng> == to infinitive
        <inf5 fre> == "<args rest first prep>" infinitif
        <inf6 eng> == infinitive
        <inf6 fre> == "<args rest first prep>" infinitif
        <inf7 eng> == to infinitive
        <inf8 eng> == infinitive
        <inf9 eng> == to infinitive
        <inf10 fre> == de infinitif
        <inf11 fre> == infinitif
        <inf12 fre> == "<args rest first prep>" infinitif
        <inf13 eng> == to infinitive
        <inf13 fre> == "<args rest rest first prep>" infinitif
        <inf14 eng> == infinitive
        <inf14 fre> == "<args rest rest first prep>" infinitif.

NP_INF:
        <inf1 eng> == np to infinitive
        <inf2 eng> == np infinitive.

GER:
        <ger1 eng> == gerundive
        <ger2 eng> == "<args rest first prep>" gerundive
        <ger3 eng> == gerundive / possessive + gerundive
        <ger4 eng> == "<args rest first prep>" gerundive / possessive +
                      gerundive.

NP:
        <cat> == np
        <case> == accusative.

PP:
        <cat> == pp.

VERB:
        <> == '* Undefined *'
        <args first syn case> == nominative
        <args first syn> == NP:<>
        <args rest> == nil.

TR_VERB_1:
        <> == VERB
        <args rest first syn> == NP:<>
        <args rest rest> == nil.

VERB_/DE:
        <> == TR_VERB_1
        <args rest first syn> == NP:<>
        <args rest first prep> == PREP:<none "<lang>">.

VERB_/DE_COMP_1:
        <> == VERB_/DE
        <args rest first that> == THAT:<that1 "<lang>">
        <args rest first inf> == INF:<inf1 "<lang>">
        <args rest first ger> == GER:<ger3 "<lang>">.

VERB_ABOUT/A:
        <> == TR_VERB_1
        <args rest first syn> == PP:<>
        <args rest first prep> == PREP:<about1 "<lang>">.

VERB_ABOUT/A_COMP_1:
        <> == VERB_ABOUT/A
        <args rest first that> == THAT:<that1 "<lang>">
        <args rest first inf> == INF:<inf5 "<lang>">
        <args rest first ger> == GER:<ger2 "<lang>">.

VERB_ABOUT/DE:
        <> == TR_VERB_1
        <args rest first syn> == PP:<>
        <args rest first prep> == PREP:<about2 "<lang>">.

VERB_ABOUT/DE_COMP_1:
        <> == VERB_ABOUT/DE
        <args rest first that> == THAT:<that2 "<lang>">
        <args rest first inf> == INF:<inf10 "<lang>">
        <args rest first ger> == GER:<ger4 "<lang>">.

VERB_ON/SUR: 
        <> == TR_VERB_1
        <args rest first syn> == PP:<>
        <args rest first prep> == PREP:<on "<lang>">.

VERB_TO/A:
        <> == TR_VERB_1
        <args rest first syn> == PP:<>
        <args rest first prep> == PREP:<to "<lang>">.

VERB_TO/A_COMP_1:
        <> == VERB_TO/A
        <args rest first inf> == INF:<inf13  "<lang>">.

TR_VERB_2:
        <> == TR_VERB_1
        <args rest rest first syn> == PP:<>
        <args rest rest rest> == nil.

VERB_DIR_TO/A:
        <> == TR_VERB_2
        <args rest first> == TR_VERB_1
        <args rest rest first> == VERB_TO/A:<args rest first>.

VERB_DIR_TO/A_COMP_1:
        <> == VERB_DIR_TO/A
        <args rest rest first inf> == VERB_TO/A_COMP_1:<args rest first inf>.

ENG_VERB_SB_DIR:
        <> == TR_VERB_2
        <args rest first> == <args rest rest first>
        <args rest first syn case> == dative
        <args rest rest first> == TR_VERB_1:<args rest first>.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

BRING_1:
    <> == VERB_DIR_TO/A
    <trans eng> == "Bring_1:<>"
    <trans fre> == "Apporter:<>".

BRING_2:
    <> == ENG_VERB_SB_DIR
    <trans eng> == "Bring_2:<>"
    <trans fre> == BRING_1.

Bring_1:
    <> == BRING_1
    <lang> == eng
    <root> == bring.

Bring_2:
    <> == BRING_2
    <lang> == eng
    <root> == Bring_1.

Apporter:
    <> == BRING_1
    <lang> == fre
    <root> == apport.

COMPLAIN:
    <> == VERB_ABOUT/DE_COMP_1
    <trans eng> == "Complain:<>"
    <trans fre> == "Se_plaindre:<>".

Complain:
    <> == COMPLAIN
    <lang> == eng
    <root> == complain.

Se_plaindre:              % something needs to be said about reflexive
    <> == COMPLAIN
    <lang> == fre
    <root> == plaind.

GIVE_1:
    <> == VERB_DIR_TO/A
    <trans eng> == "Give_1:<>"
    <trans fre> == "Donner:<>".

GIVE_2:
    <> == ENG_VERB_SB_DIR
    <trans eng> == "Give_2:<>"
    <trans fre> == "Donner:<>".

Give_1:
    <> == GIVE_1
    <lang> == eng
    <root> == give.

Give_2:
    <> == GIVE_2
    <lang> == eng
    <root> == Give_1.

Donner:
    <> == GIVE_1
    <lang> == fre
    <root> == donn.

LEAD_1:
    <> == VERB_TO/A
    <trans eng> == "Lead_1:<>"
    <trans fre> == "Aboutir:<>".

LEAD_2:
    <> == VERB_DIR_TO/A_COMP_1
    <trans eng> == "Lead_2:<>"
    <trans fre> == "Amener:<>".

Lead_1:
    <> == LEAD_1
    <lang> == eng
    <root> == lead.

Lead_2:
    <> == LEAD_2
    <lang> == eng
    <root> == Lead_1.

Aboutir:
    <> == LEAD_1
    <lang> == fre
    <root> == about.

Amener:
    <> == LEAD_2
    <lang> == fre
    <root> == amen.

RELY:
    <> == VERB_ON/SUR
    <trans eng> == "Rely:<>"
    <trans fre> == "Compter:<>".

Rely:
    <> == RELY
    <lang> == eng
    <root> == rely.

Compter:
    <> == RELY
    <lang> == fre
    <root> == compt.

REMEMBER:
    <> == VERB_/DE_COMP_1
    <trans eng> == "Remember:<>"
    <trans fre> == "Se_souvenir:<>".

Remember:
    <> == REMEMBER
    <lang> == eng
    <root> == remember.

Se_souvenir:              % something needs to be said about reflexive
    <> == REMEMBER
    <lang> == fre
    <root> == souven
    <args rest first syn> == PP:<>.

THINK:
    <> == VERB_ABOUT/A_COMP_1
    <trans eng> == "Think:<>"
    <trans fre> == "Penser:<>".

Think:
    <> == THINK
    <lang> == eng
    <root> == think.

Penser:
    <> == THINK
    <lang> == fre
    <root> == pens.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# hide  PREP THAT INF NP_INF GER NP PP VERB TR_VERB_1 TR_VERB_2 VERB_/DE
        VERB_/DE_COMP_1 VERB_ABOUT/A VERB_ABOUT/A_COMP_1 VERB_ABOUT/DE
        VERB_ABOUT/DE_COMP_1 VERB_ON/SUR VERB_TO/A VERB_TO/A_COMP_1
        VERB_DIR_TO/A VERB_DIR_TO/A_COMP_1 ENG_VERB_SB_DIR BRING_1
        BRING_2 COMPLAIN GIVE_1 GIVE_2 LEAD_1 LEAD_2 RELY REMEMBER THINK.

# show  <trans eng root>
        <trans fre root>
        <args first syn cat>
        <args first syn case>
        <args rest first inf>
        <args rest first ger>
        <args rest first that>
        <args rest first prep>
        <args rest first syn cat>
        <args rest first syn case>
        <args rest rest first inf>
        <args rest rest first ger>
        <args rest rest first that>
        <args rest rest first prep>
        <args rest rest first syn cat>
        <args rest rest first syn case>.

% The next line is the Revision Control System Id: do not delete it.
% $Id: archive.dtr,v 1.1 1997/04/09 20:40:33 root Exp $