% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            catalann.dtr                                             %
% Purpose:         derived fe/male forms of nouns for persons in Catalan    %
% Author:          Gerald Gazdar & Max Wheeler, April 1995                  %
% Email:           geraldg@cogs.sussex.ac.uk, maxw@cogs.sussex.ac.uk        %
% Address:         COGS, Sussex University, Brighton BN1 9QH, UK            %
% Documentation:   Max Wheeler draft chapter of "Catalan Reference Grammar" %
% Version:         2.00 (June 1996)                                         %
%                                                                           %
%      Copyright (c) University of Sussex 1995.  All rights reserved.       %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% What follows is a second attempt to encode in DATR the facts concerning
% Catalan derived nouns for females (occasionally males) as set out in the
% beginning of Max Wheeler's March 1995 draft chapter on gender for his
% "Catalan Reference Grammar" (with A. Yates and N. Dols).

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# nc seq node:<name>.

Word:
    <> ==

    % by default, the citation form is spelt the same as the name of the
    % node:

    <citation form> == Idem:<"<name>">

    % to get the ortographic form, apply the Orthography function to the
    % relevant word value:

    <orth> == Orthography:<"<word>" !>.


# vars $sex: male female.

Noun:
    <> == Word
    <cat> == noun

    % by default, gender is determined by sex, in the obvious way:

    <gender male> == masc
    <gender female> == femn

    % by default, the gloss is just the sex concatenated with the
    % 'meaning':

    <gloss $sex> == $sex "<meaning>"

    % to arrive at the stem for the sex-alternant, apply MakeStem to the
    % citation form (and the diacritic, if any):

    <stem> == MakeStem:<"<citation form>" "<diacritic>" !>

    % by default, the word for the sex-alternant is created by
    % adding the relevant suffix to the stem:

    <word> == "<stem>" "<suffix>".


% Nouns with 'common' gender, i.e., unspecified for either sex or gender:

NounC:
    <> == Noun
    <gender> ==
    <gloss> == "<meaning>"
    <word> == "<citation form>".

% Nouns with fixed masculine gender, but unspecified for sex:

NounCM:
    <> == NounC
    <gender> == masc.

% Nouns with fixed feminine gender, but unspecified for sex:

NounCF:
    <> == NounC
    <gender> == femn.

% Nouns whose basic form refers to a female:

NounF:
    <> == Noun
    <suffix> == o t
    <word female> == "<citation form>".

% Nouns whose basic form refers to a male:

NounM:
    <> == Noun
    <suffix> == a
    <word male> == "<citation form>".

NounEssa:
    <> == NounM
    <suffix> == e s s a.

NounIna:
    <> == NounM
    <suffix> == i n a.

NounW:
    <> == NounM
    <stem> == "<citation form>".

NounS:
    <> == NounM
    <stem> == "<citation form>" s.

NounL:
    <> == NounM
    <stem> == "<citation form>" [dot] l.

Noun-:
    <> == NounM
    <diacritic> == -.

NounRiu:
    <> == Noun-
    <suffix> == r i u.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% To prepare the stem, reverse it, apply the EndStem function to the reversed
% string, and then reverse the result so as to restore the original segment
% order:

MakeStem:
    <> == Reverse:<EndStem:<Reverse:<!>>>.

%   variable over (stressed) vowels used by EndStem:

# vars $v: a e i o u.

EndStem:
    <> == Voiced:<>

    % delete an (unstressed) final vowel:
    <a> == Idem:<>  % needed for poeta (1.1.2), abella (1.1.3), etc. ??
                    % or could use <diacritic> to nuke specific vowels
    <e> == Idem:<>
    <o> == Idem:<>

    % map a final 'u' to a final 'v':
    <u> == v Idem:<>
    % unless it is marked for deletion by the diacritic:
    <- u> == Idem:<>
    % which is also used to delete final 'or' when specified:
    <- r o> == Idem:<>

    % append 'n' to an acute vowel:
    <$v [acute]> == n $v [acute] Idem:<>

    % and map final 'oleg' to 'olog':
    <g e l o> == g o l o Idem:<>.

Voiced:
    <> == Idem
% Next rule commented out to prevent 'fotograva' (which is wrong):
%   <f $v> == v Idem:<$v>
    <t $v> == d Idem:<$v>
    <p $v> == b Idem:<$v>
    <c $v> == g Idem:<$v>.


% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# vars $s1: a b c d e f g h i j k l m n o p q r s t u v w x y z.
# vars $s2: a b c d e f g h i j k l m n o p q r s t u v w x y z.
# vars $ns: n s.
# vars $w:  a e i o u.
# vars $ae: a e.
# vars $iu: i u.
# vars $a:  [acute] [grave].

Orthography:
    <!> ==
    <$i> == $i <>
    <$i !> == $i
    <$v i i> == $v [dots] i <>
    <$v $a $iu $s1 $s2> == $v [dots] $iu $s1 $s2 <>
% Following rule much too general -- deleted accents all over the place
%   <$a $v $s1 $s2> == $v $s1 $s2 <>
% Replaced by the following three rules:
    <$a $v $ae> == $v $ae <>
    <$a $v $ns $w> == $v $ns $w <>
    <$a $v s s $w> == $v s s $w <>.


% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# atom Aramaean Aztec Belgian Chaldean Galician Galilean Gaul Greek Hebrew
  Indo-European Jew Manichean Norwegian Pharisee Philistine Pigmy Russian
  Slav Swiss.

# vars $word: orth gloss gender word stem.

Abat:
    <> == NounEssa
    <meaning> == abbot.

Abella:
    <> == NounF
    <meaning> == bee.

Actor:
    <> == NounRiu
    <meaning> == actor.

Alcalde:
    <> == NounEssa
    <meaning> == mayor.

% Are the following pair of entries are dialectal or stylistic alternants?

Ambaixador1:
    <> == NounM
    <meaning> == ambassador.

Ambaixador2:
    <> == NounRiu
    <meaning> == Ambaixador1.

Amic:
    <> == NounM
    <meaning> == friend.

Amo:
    <> == NounM
    <gloss male> == master
    <$word female> == "Mestressa:<$word female>".

Andreu:
    <> == NounW
    <meaning> == given name.

Aprenent:
    <> == NounM
    <meaning> == apprentice.

Arameu:
    <> == Noun-
    <meaning> == Aramaean.

Asteca:
    <> == NounC
    <meaning> == Aztec.

Ateu:
    <> == Noun-
    <meaning> == atheist.

Avi:
    <> == NounM
    <stem> == [grave] <citation form>
    <meaning> == grandparent.

Baro:
    <> == NounEssa
    <citation form> == b a r [acute] o
    <meaning> == baron.

Bedui:
    <> == NounM
    <citation form> == b e d u [acute] i
    <meaning> == bedouin.

Belga:
    <> == NounC
    <meaning> == Belgian.

Bordegas:
    <> == NounS
    <citation form> == b o r d e g [grave] a s
    <meaning> == youth.

Borrec:
    <> == NounM
    <meaning> == yearling.

Bruixa:
    <> == NounF
    <gloss female> == witch
    <gloss male> == wizard.

Bus:
    <> == NounS
    <meaning> == diver.

Caldeu:
    <> == Noun-
    <meaning> == Chaldean.

Capatas:
    <> == NounS
    <citation form> == c a p a t [grave] a s
    <meaning> == overseer.

Camil:
    <> == NounL
    <meaning> == given name.

% The analysis is not currently capturing the fact that nouns that end
% in the -aire agent suffix belong to NounC:

Captaire:
    <> == NounC
    <meaning> == beggar.

Carca:
    <> == NounC
    <meaning> == reactionary.

Cardioleg:
    <> == NounM
    <citation form> == c a r d i [grave] o l e g
    <meaning> == cardiologist.

Cec:
    <> == NounM
    <meaning> == blind person.

Ciril:
    <> == NounL
    <meaning> == given name.

Collega:
    <> == NounC
    <citation form> == c o l [dot] l e g a
    <meaning> == colleague.

Company:
    <> == NounM
    <meaning> == companion.

Comte:
    <> == NounEssa
    <meaning> == count.

Criatura:
    <> == NounCF
    <meaning> == baby.

Democrata:
    <> == NounC
    <citation form> == d e m [grave] o c r a t a
    <meaning> == democrat.

% Are the following two entries dialect alternants?

Deu1:
    <> == Noun-
    <citation form> == d [acute] e u
    <meaning> == god.

Deu2:
    <> == Deu1
    <suffix> == NounEssa.

Detectiu:
    <> == NounM
    <meaning> == detective.

Diable:
    <> == NounEssa
    <meaning> == devil.

Diaca:
    <> == NounEssa
    <stem> == d i a c o n
    <meaning> == deacon.

Dida:
    <> == NounF
    <gloss female> == wet nurse
    <gloss male> == husband of wet nurse.

Dona:
    <> == NounF
    <meaning> == person/spouse
    <$word male> == "Home:<$word male>".

Dormilec:
    <> == NounM
    <meaning> == sleepyhead.

Dormilega:
    <> == NounC
    <meaning> == Dormilec.

Druida:
    <> == NounEssa
    <stem> == d r u [dots] i d
    <meaning> == druid.

Duc:
    <> == NounEssa
    <stem> == d u q u
    <meaning> == duke.

Electricista:
    <> == NounC
    <meaning> == electrician.

Emperador:
    <> == NounRiu
    <meaning> == emperor.

Enemic:
    <> == NounM
    <meaning> == enemy.

Esclau:
    <> == NounM
    <meaning> == slave.

Eslau:
    <> == NounM
    <meaning> == Slav.

Extra:
    <> == NounC
    <meaning> == film extra.

Fariseu:
    <> == Noun-
    <meaning> == Pharisee.

Filisteu:
    <> == Noun-
    <meaning> == Philistine.

Fill:
    <> == NounM
    <meaning> == offspring.

Fotograf:
    <> == NounM
    <citation form> == f o t [grave] o g r a f
    <meaning> == photographer.

Fura:
    <> == NounF
    <meaning> == ferret.

Gal:
    <> == NounL
    <meaning> == Gaul.

Galileu:
    <> == Noun-
    <meaning> == Galilean.

Gall:
    <> == NounIna
    <meaning> == chicken.

Gallec:
    <> == NounM
    <meaning> == Galician.

Ganapia:
    <> == NounC
    <citation form> == g a n [grave] a p i a
    <meaning> == childish person.

% The analysis is not currently capturing the fact that nouns that end
% in -ant, -ent, or -int, belong to the NounC class, by default:

Gerent:
    <> == NounC
    <meaning> == manager.

Germa:
    <> == NounM
    <citation form> == g e r m [acute] a
    <meaning> == sibling.

Gimnasta:
    <> == NounC
    <meaning> == gymnast.

Gos:
    <> == NounS
    <meaning> == dog.

Grec:
    <> == NounM
    <meaning> == Greek.

Guatlla:
    <> == NounF
    <meaning> == quail.

Hebreu:
    <> == Noun-
    <meaning> == Hebrew.

% The following pair of entries are dialectal alternants

Hereu1:
    <> == NounM
    <meaning> == heir.

Hereu2:
    <> == NounW
    <meaning> == Hereu1.

Heroi:
    <> == NounIna
%   there's an issue about the final vowel here:
    <meaning> == hero.

Hipocrita:
    <> == NounC
    <citation form> == h i p [grave] o c r i t a
    <meaning> == hypocrite.

Home:
    <> == NounM
    <meaning> == person/spouse
    <$word female> == "Dona:<$word female>".

% Are the following two entries dialect alternants?

Hoste1:
    <> == NounEssa
    <meaning> == host.

Hoste2:
    <> == NounEssa
    <meaning> == lodger.

Indigena:
    <> == NounC
    <citation form> == i n d [acute] i g e n a
    <meaning> == native.

Individu:
    <> == NounCM
    <meaning> == individual.

Indoeuropeu:
    <> == Noun-
    <meaning> == Indo-European.

Institutor:
    <> == NounRiu
    <meaning> == tutor.

Judoka:
    <> == NounC
    <meaning> == practitioner of judo.

Jueu:
    <> == NounM
    <meaning> == Jew.

Jutge:
    <> == NounEssa
    <meaning> == judge.

Llec:
    <> == NounM
    <meaning> == lay person.

Llop:
    <> == NounM
    <meaning> == wolf.

Lluis:
    <> == NounM
    <citation form> == l l u [grave] i s
    <meaning> == given name.

Maniqueu:
    <> == Noun-
    <meaning> == Manichean.

Manyac:
    <> == NounM
    <meaning> == sweetheart.

Marcel:
    <> == NounL
    <meaning> == given name.

Marit:
    <> == NounM
    <gloss male> == husband
    <$word female> == "Muller:<$word female>".

Merla:
    <> == NounF
    <meaning> == blackbird.

Mestressa:
    <> == NounF
    <gloss female> == mistress
    <$word male> == "Amo:<$word male>".

Metge:
    <> == NounEssa
    <meaning> == doctor.

Monjo:
    <> == NounM
    <gloss male> == monk
    <gloss female> == nun.

Muller:
    <> == NounF
    <gloss female> == wife
    <$word male> == "Marit:<$word male>".

Nebot:
    <> == NounM
    <gloss male> == nephew
    <gloss female> == niece.

Noi:
    <> == NounM
    <meaning> == child.

Noruec:
    <> == NounM
    <meaning> == Norwegian.

Ogre:
    <> == NounEssa
    <meaning> == ogre.

Oncle:
    <> == NounM
    <gloss male> == uncle
    <$word female> == "Tia:<$word female>".

Orfe:
    <> == NounM
    <stem> == [grave] o r f en
    <meaning> == orphan.

Os:
    <> == NounS
    <citation form> == [acute] o s
    <meaning> == bear.

Pages:
    <> == NounM
    <citation form> == p a g [grave] e s
    <meaning> == farmer.

Pastifa:
    <> == NounC
    <meaning> == botcher.

Pau:
    <> == NounM
    <stem> == p a u l
    <meaning> == given name.

Pediatre:
    <> == NounM
    <meaning> == paediatrician.

Perdiu:
    <> == NounF
    <stem> == p e r d i g
    <meaning> == partridge.

Persona:
    <> == NounCF
    <meaning> == person.

Pigmeu:
    <> == Noun-
    <meaning> == Pigmy.

Poeta:
    <> == NounEssa
    <meaning> == poet.

Pompeu:
    <> == NounM
    <stem> == p o m p e i
    <meaning> == given name.

Posses:
    <> == NounS
    <citation form> == p o s s [acute] e s
    <meaning> == person possessed.

Princep:
    <> == NounM
    <citation form> == p r [acute] i n c e p
    <stem> == p r i n c e s
    <meaning> == prince.

Profes:
    <> == NounS
    <citation form> == p r o f [acute] e s
    <meaning> == person who has taken vows.

Profeta:
    <> == NounEssa
    <meaning> == prophet.

Pubilla:
    <> == NounF
    <meaning> == heir
    <$word male> == "Hereu1:<$word male>".

Pupil:
    <> == NounL
    <meaning> == ward.

Rei:
    <> == NounM
    <stem> == r e i n
    <meaning> == monarch.

Reu:
    <> == Noun-
    <meaning> == culprit.

% The following pair of entries are dialectal alternants

Romeu1:
    <> == NounM
    <meaning> == pilgrim.

Romeu2:
    <> == NounW
    <meaning> == Romeu1.

Rus:
    <> == NounS
    <meaning> == Russian.

Santedat:
    <> == NounCF
    <meaning> == holiness.

Serf:
    <> == NounM
    <stem> == s e r v
    <meaning> == serf.

Socioleg:
    <> == NounM
    <citation form> == s o c i [grave] o l e g
    <meaning> == sociologist.

Suis:
    <> == NounS
    <citation form> == s u [acute] i s
    <meaning> == Swiss.

Talos:
    <> == NounS
    <citation form> == t a l [grave] o s
    <meaning> == dolt.

Televident:
    <> == NounC
    <meaning> == television viewer.

Terapeuta:
    <> == NounC
    <meaning> == therapist.

Terrissaire:
    <> == NounC
    <meaning> == potter.

Tia:
    <> == NounF
    <gloss female> == aunt
    <$word male> == "Oncle:<$word male>".

Tigre:
    <> == NounEssa
    <meaning> == tiger.

Tsar:
    <> == NounIna
    <meaning> == czar.

Vianant:
    <> == NounC
    <meaning> == pedestrian.

Victima:
    <> == NounCF
    <citation form> == v [acute] i c t i m a
    <meaning> == victim.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Two utility functions

# vars $n: 1 2 3.

Idem:
    <> ==
    <$i> == $i <>
    <$i !> == $i !
    <$i $sex> == $i <>
%   Next line is to remove codes from the name of the node:
    <$i $n> == $i .

Reverse:
    <> ==
    <$i> == <> $i
    <$i !> ==  $i.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

#   show

    <gloss male>
    <gender male>
    <orth male>
    <gloss female>
    <gender female>
    <orth female>.


#   hide

    Idem Reverse EndStem MakeStem Voiced Word Noun NounC NounCM NounCF
    NounM NounF NounEssa NounIna NounRiu NounW NounS NounL Noun-
    Orthography.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% The next line is the Revision Control System Archive Id: do not delete it.
% $Id: archive.dtr,v 1.1 1997/04/09 20:40:33 root Exp $