% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
%                                                                           %
% File:            baoule.dtr                                               %
% Purpose:         inflection and derivation in Baoule                      %
% Author:          Dafydd Gibbon, M.L.N'Guessan, 25th January 1993          %
% Email:           gibbon@spectrum.uni-bielefeld.de                         %
% Address:         Univ. Bielefeld, P 100131, D-33501, Bielefeld, Germany   %
% Version:         1.01                                                     %
%                                                                           %
%   Copyright (c) University of Bielefeld 1993.  All rights reserved.       %
%                                                                           %
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Generalisation hierarchy

Word:
    <> == 
    <root> == "<syllable structure>"
    <surf phon> == "<syllable structure>".

Noun:
    <> == Word
    <infl> == QLP
    <der> == QLP.

Compound_noun :
    <> == Noun
    <syllable structure> == QLP:<compound>. 

Morph_templates:
    <> == 
    <infl> == "Infl_affix"
    <der> == "Der_affix"
    <infl_tone> == "Verb_ton_mod"
    <infl_affixes> == "Verb_infl_affixes".

QLP:
    <> == 
    <infl> == [ "<root>" ] '^' "Morph_templates"
    <der>  == [ "<root>" ] '^' "Morph_templates"
    <inflex> ==          "Morph_templates:<infl_tone>" ø "<root>"
    <inflex_suffix> == [ "Morph_templates:<infl_tone>" ø "<root>" ] '^'
                       [ "Morph_templates:<infl_affixes>" ]
    <inflex_prefix> == [ "Morph_templates:<infl_affixes>" ] '^'
                       [ "Morph_templates:<infl_tone>" ø "<root>" ]
    <compound> == "<determinans syllable structure>" '^'
                  "<determinatum syllable structure>".

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Inflexional affixes

Infl_affix:
    <> == Word
    <infl plural> == m ~ u
    <infl particularizer> == b a   % Only for mass nouns
    <infl specifier> == l ~ i
    <infl particularizer plural> == [ <infl particularizer> '^' <infl  plural> ]
    <infl particularizer specifier> == [ <infl particularizer> '^'
                                        <infl specifier> ].

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Word structure templates

Segments:
    <> == 
    <surf phon> == [ 'onset:' Onset 'core:' Core ].

Onset:
    <> == 
    <surf phon> == [ 'plos:' Plosive 'liqu:' Liquid 'gl:' Glide ].

Plosive:
    <> == 
    <surf phon> == "<surf phon syll seg onset plos>".

Liquid:
    <> == 
    <surf phon> == "<surf phon syll seg onset liqu>".

Glide:
    <> == 
    <surf phon> == "<surf phon syll seg onset gl>". 

Core:
    <> == 
    <surf phon> == "<surf phon syll seg vowel>".

Prosody:
    <> == 
    <surf phon> == [ 'nas:' Nasal 'tone:' Tone ].

Nasal:
    <> == 
    <surf phon> == "<surf phon syll pros nasal>".

Tone:
    <> == 
    <surf phon> == "<surf phon syll pros tone>".

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Derivational affixes        

Der_affix:
    <> == Word
    <der action process> == l e 
    <der agent> == f w e
    <der means manner place> == w l e
    <der state> == l w a.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Verbal inflections and derivations

Verb:
    <> == Word  
    <inflex> == QLP
    <inflex_suffix> == QLP 
    <inflex_prefix> == QLP.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Verbal inflectional affixes

Verb_infl_affixes:
    <> == Word
    <infl_affixes perfective> == [ mid-low_tone ] ø a
    <infl_affixes imperfective> == [ mid-high_tone ] ø su
    <infl_affixes factual_past> == [ mid-low_tone ] ø li.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Verbal tonal modals

Verb_ton_mod:
    <> == Word
    <infl_tone stative> == [ mid-low_tone ]
    <infl_tone perfective> == <infl_tone stative>
    <infl_tone factual_past> == <infl_tone stative>
    <infl_tone certaintive> == [ high_tone ] '^' <infl_tone stative>  
    <infl_tone subjunctive> == [ mid-high_tone ] '^' [ high_tone ]
    <infl_tone imperfective> == <infl_tone certaintive>
    <infl_tone factual_past> == <infl_tone stative>.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Segments

% Consonants

% Default consonant: /t/

C: 
    <> ==  
    <contin> ==  [ -contin ]
    <son> ==  [ -son ]
    <reson> ==  [ -reson ]
    <lab> ==  [ -lab ]
    <cor> ==  [ +cor ]   
    <vel> ==  [ -vel ]
    <nas> ==  [ -nas ]
    <faisceau> ==  "<contin>" "<son>" "<reson>" "<lab>" "<cor>" "<vel>" "<nas>"
    <segment> ==  t.

P_p:
    <> ==  P_t
    <lab> ==  [ +lab ]
    <cor> ==  [ -cor ]
    <segment> ==  p.

P_t:
    <> == C.

P_c:
    <> == P_t
    <cor> == P_p
    <segment> == c.

P_k:
    <> == P_t      
    <cor> == P_p
    <vel> == [ +vel ]
    <segment> == k.

P_kp:
    <> == P_k
    <lab> == P_p
    <segment> == kp.

P_b:
    <> == P_p
    <son> == P_d
    <segment> == b.

P_d:
    <> == P_t
    <son> == [ +son ]
    <segment> == d.

P_J:
    <> == P_c
    <son> == P_d
    <segment> == J.

P_g:
    <> == P_k
    <son> == P_d
    <segment> == g.

P_gb:
    <> == P_kp
    <son> == P_d
    <segment> == gb.

P_f:
    <> == P_p
    <contin> == P_s
    <segment> == f.

P_s:
    <> == P_t
    <contin> == [ +contin ]
    <segment> == s.

P_l:
    <> == P_d
    <reson> == [ +reson ]
    <segment> == l.

P_j:
    <> == P_l
    <contin> == P_s
    <segment> == j. 

P_w:
    <> == P_gb
    <contin> == P_j
    <reson> == P_j
    <segment> == w.

P_m:
    <> == P_b
    <nas> == [ +nas ]
    <segment> == m.  

% Vowels

% Default vowel: /e/

V: 
    <> == 
    <high> == [ +high ]
    <mid> == [ +mid ]
    <ant> == [ +ant ]
    <lab> == [ -lab ]
    <nas> == [ -nas ]
    <faisceau> == "<high>" "<mid>" "<ant>" "<lab>" "<nas>"
    <segment> == e.

P_i:
    <> == P_e
    <mid> == [ -mid ]
    <segment> == i.

P_e:
    <> == V.

P_E:
    <> == P_e
    <high> == [ -high ]
    <segment> == E.

P_a:
    <> == P_E
    <mid> == P_i
    <ant> == P_u
    <segment> == a.

P_o:
    <> == P_e
    <ant> == [ -ant ]
    <lab> == [ +lab ]
    <segment> == o.

P_O:
    <> == P_o
    <high> == P_u
    <segment> == O.

P_u:
    <> == P_o
    <mid> == P_i
    <segment> == u.

P_~i:
    <> == P_i
    <nas> == [ +nas ]
    <segment> == ~i.

P_~E:
    <> == P_E 
    <nas> == P_~i
    <segment> == ~E.

P_~a:
    <> == P_a
    <nas> == P_~i
    <segment> == ~a. 

P_~O:
    <> == P_O
    <nas> == P_~i
    <segment> == ~O.

P_~u:
    <> == P_u
    <nas> == P_~i
    <segment> == ~u.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

% Lemma hierarchy

Bla:
    <> == Noun
    <gloss> == femme 'Frau' woman signora    
    <surf orth> == b l a
    <syllable structure> == bla
    <surf phon onset plos> == b
    <surf phon onset liquid> == l
    <surf phon core vowel> == a
    <surf phon pros tone> == [ mid_tone ].

Ablealje:
    <> == Compound_noun
    <gloss> == corn_meal  
    <determinans> == "Able:<>"
    <determinatum> == "Alje:<>".

Able:
    <> == Noun
    <gloss> == corn
    <surf orth> == able
    <syllable structure> == a '^' ble
    <surf phon core vowel> == a
    <surf phon onset plos> == b
    <surf phon onset liquid> == l
    <surf phon core vowel> ==e.

Alje:
    <> == Noun
    <gloss> == meal
    <surf orth> == alie
    <syllable structure> == a '^' lje
    <surf phon core vowel> == a
    <surf phon onset liquid> == l
    <surf phon onset glide> == j
    <surf phon core vowel> == e.

Si:
    <> == Noun
    <gloss> == father
    <surf orth> == si
    <syllable structure> == si
    <surf phon onset plos> == s
    <surf phon core vowel> == i.

SiklO:
    <> == Compound_noun
    <determinans> == "Si:<>"
    <determinatum> == "KlO:<>".

Boli:
    <> == Noun
    <gloss> == sheep
    <surf orth> ==boli
    <syllable structure> == bo '^' li
    <surf phon onset plos> == b
    <surf phon core vowel> == o
    <surf phon onset liquid> == l
    <surf phon core vowel> == i.

KlO:
    <> == Noun
    <gloss> == village
    <surf orth> == klO
    <syllable structure> == klO
    <surf phon onset plos> == k
    <surf phon onset liquid> == l
    <surf phon core vowel> == O.

L~ati:
    <> == Verb
    <gloss> == walk
    <surf orth> == l~ati
    <syllable structure> == l~a '^' ti
    <surf phon onset liquid> == l
    <surf phon pros nasal> == ~
    <surf phon core vowel> == a
    <surf phon onset plos> == t
    <surf phon core vowel> == i.

% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %

# show <surf phon>.

# hide

    Word Noun Compound_noun Morph_templates QLP Infl_affix Segments Onset
    Plosive Liquid Glide Core Prosody Nasal Tone Der_affix Verb C P_p P_t
    P_c P_k P_kp P_b P_d P_J P_g P_gb P_f P_s P_l P_j P_w P_m V P_i P_e
    P_E P_a P_o P_O P_u P_~i P_~E P_~a P_~O P_~u Verb_infl_affixes
    Verb_ton_mod.

% The next line is the Revision Control System Id: do not delete it.
% $Id: archive.dtr,v 1.1 1997/04/09 20:40:33 root Exp $